1 '* REV 1
2 '* FIFTY MISSION CRUSH (PC VERSION) COPYRIGHT 12-26-1985 BY JOHN R. GRAY
6 SCREEN 1:CLS:LOCATE 10,10:PRINT "FIFTY MISSION CRUSH v.1.3":LOCATE 12,6:PRINT "GAME DESIGN & PROGRAMMING BY":LOCATE 14,13:PRINT "JOHN R. GRAY":FOR I = 1 TO 2500:NEXT I
8 KEY OFF:GOSUB 58000
9 MISSION=MISSION+1
10 CLS:SCREEN 2:GOSUB 50000:PLOTX=14:PLOTY=7:GOSUB 40002:GOSUB 50110:GOTO 1000
12  SOUND 37,4:RETURN
14 FOR S=1 TO 5:SOUND 37,1:SOUND 32757,1:SOUND 47,1:NEXT S:RETURN
15  FOR S=1 TO 4:SOUND 65,1:SOUND 32757,1:SOUND 60,1:NEXT S:RETURN
20 IF PLOTX=38 AND PLOTY=2 THEN 5010
21 IF BFLAG=1 THEN RETURN
22 IF DRN=T THEN:VAH=VH:VAV=VV:GOSUB 15
23 IF DRN<>T THEN RETURN
24 T=75:IF BANG+((T*3)+GN )>290 THEN GOSUB 10000:GOSUB 12:BFLAG=1:GOSUB 27
25 RETURN
26 '*
27 FXR=FXRN+4:FYR=FYRN+5:PUT (FXR,FYR),FLA,XOR:FOR L=1 TO 100:NEXT L:PUT (FXR,FYR),FLA,XOR
28 PUT (FXRN,FYRN),SMOKE,XOR:PUT (FXRN,FYRN),SMOKE,XOR:IF FYRN>178 THEN RETURN
29 FYRN=FYRN+4:GOTO 28
30 PUT ((VNH)+(VHP),(VNV)+(VVP)),SMOKE,XOR
31 PUT ((VNH)+(VHP),(VNV)+(VVP)),SMOKE,XOR:IF VNV+VVP>178 THEN RETURN
32 VVP=VVP+4:GOTO 30
80 IF PLOTX>40 THEN PLOTX=40:PLOTY=PLOTY-1:BEEP:FUEL=FUEL+42
81 IF PLOTY>25 THEN PLOTY=25:PLOTX=PLOTX-1:BEEP:FUEL=FUEL+42
82 RETURN
83 IF PLOTX<1 THEN PLOTX=1:PLOTY=PLOTY-1:BEEP:FUEL=FUEL+42
84 IF PLOTY>25 THEN PLOTY=25:PLOTX=PLOTX+1:BEEP:FUEL=FUEL+42
85 RETURN
86 IF PLOTX<1 THEN PLOTX=1:PLOTY=PLOTY+1:BEEP:FUEL=FUEL+42
87 IF PLOTY<1 THEN PLOTY=1:PLOTX=PLOTX+1:BEEP:FUEL=FUEL+42
88 RETURN
90 '*
91 IF PLOTX>40 THEN PLOTX=40:BEEP:ER=1:FUEL=FUEL+30:RETURN
92 IF PLOTX<1 THEN PLOTX=1:BEEP:ER=1:FUEL=FUEL+30:RETURN
93 IF PLOTY>25 THEN PLOTY=25:BEEP:ER=1:FUEL=FUEL+30:RETURN
94 IF PLOTY<1 THEN PLOTY=1:BEEP:ER=1:FUEL=FUEL+30:RETURN
95 IF PLOTX>40 THEN PLOTX=40:PLOTY=PLOTY+1:BEEP:FUEL=FUEL+42
96 IF PLOTY<1 THEN PLOTY=1:PLOTX=PLOTX-1:BEEP:FUEL=FUEL+42
97 RETURN
100 '*
102 LINE ((1+LAX),(1+LAY))-((7+LAX),(1+LAY)),2:LINE ((1+LAX),(1+LAY))-((1+LAX),(7+LAY)),2:LINE ((0+LAX),(6+LAY))-((6+LAX),(0+LAY)),2
104 RETURN
106 '*
108 LINE ((2+LFX),(0+LFY))-((5+LFX),(0+LFY)),2:LINE ((2+LFX),(2+LFY))-((5+LFX),(2+LFY)),2:LINE ((2+LFX),(4+LFY))-((5+LFX),(4+LFY)),2:LINE ((2+LFX),(6+LFY))-((5+LFX),(6+LFY)),2
110 LINE ((2+LFX),(0+LFY))-((2+LFX),(6+LFY)),2:LINE ((5+LFX),(0+LFY))-((5+LFX),(6+LFY)),2
112 RETURN
114 '*
116 LINE ((1+LRX),(0+LRY))-((1+LRX),(0+LRY)),2:LINE ((2+LRX),(1+LRY))-((3+LRX),(1+LRY)),2:LINE ((5+LRX),(1+LRY))-((6+LRX),(0+LRY)),2:LINE ((1+LRX),(7+LRY))-((2+LRX),(7+LRY)),2
118 LINE ((3+LRX),(6+LRY))-((4+LRX),(5+LRY)),2:LINE ((5+LRX),(6+LRY))-((6+LRX),(7+LRY)),2:LINE ((4+LRX),(2+LRY))-((4+LRX),(4+LRY)),2
120 RETURN
130 '*
140 LINE ((0+LGX),(0+LGY))-((7+LGX),(7+LGY)),2:LINE ((0+LGX),(7+LGY))-((7+LGX),(7+LGY)),2:LINE ((0+LGX),(7+LGY))-((3+LGX),(4+LGY)),2
145 LINE ((2+LGX),(6+LGY))-((5+LGX),(6+LGY)),2
150 RETURN
152 '*
154 BEEP:BEEP:RETURN
160 '*
162 RANDOMIZE TIMER:RN=INT(17*RND(0))+1:RETURN
164 '*
166 RANDOMIZE TIMER:RN=INT(100*RND(0))+1:RETURN
168 '*
170 RANDOMIZE TIMER:FXRN=INT(300*RND(0))+1:RETURN
171 '*
172 RANDOMIZE TIMER:FYRN=INT(183*RND(0))+1:RETURN
173 '*
174 RANDOMIZE TIMER:DRN=INT(66*RND(0))+1:RETURN
175 '*
176 RANDOMIZE TIMER:FHRN=INT(1000*RND(0))+1:RETURN
178 '*
180 RANDOMIZE TIMER:RN=INT(12*RND(0))+1:RETURN
182 '*
184 RANDOMIZE TIMER:VRN=INT(5*RND(0))+1:RETURN
186 '*
188 RANDOMIZE TIMER:HRN=INT(20*RND(0))+1:RETURN
192 '*
194 RANDOMIZE TIMER:RN=INT(75*RND(0))+1:RETURN
196 '*
198 RANDOMIZE TIMER:RN=INT(70*RND(0))+1:RETURN
1000 '*
1010 SCREEN 1,SS:COLOR 0,CL:CLS
1020 DRAW "C3"
1030 DRAW "BM32,0 G2 D6 R2 E1 R5 F1 D3 G6L14 G5 D4 R3 E2 F2 R3 F8 R15 E1 R8 G14 H8 L6 G2 L2 G17 L4 G5": DRAW "BE15":DRAW "P1,3"
1032 DRAW "C3"
1040 DRAW "BM0,64 R13 F7 E4 U3 E5 R6 F9 R8 E7 R13 F7 R11 E1 R13 F1 R19 D1 R4 D1 R2 F3 R4 E4 R2 U1 H4 U5 L9 H4 U1 E16 R6 E11 U8 H4 L7 H7 R6 U3 H5"
1060 LAX=105:LAY=49:GOSUB 100
1062 DRAW "C3"
1064 DRAW "BM66,65 E2 R3 F1 D1 G1 L3 H1
1070 '*
1075 DRAW "C3"
1080  DRAW "BM0,144 F10 E2 R3 D3 R1 U1 R2 D4 L2 U1 L1 D2 F7 D2 R1 U1 R2 D4 L2 U1 L1 D7 F4 R2 F2 D5 L3 D1 R1 D2 L4 U2 R1 U1 L3 D7 G4":DRAW "BH15":DRAW "P1,3":DRAW "C3"
1090 DRAW "BM0,140 E8 U3 H2 L2 U2 R1 U2 L4 D2 R1 D2 L2":DRAW "BF2":DRAW "P1,3":DRAW "C3"
1100 DRAW "BM0,120 R7 E2 R4 E2 R4 F3 D3 F6 R2 E2 R9 E1 U1 H2 U8 E2 U3 H2 U12 R2 F1 R3 E1 R7 E1 R2 D1 G3 D13 F2 E2 R23 F1 R8 H4 U5 E3 F2 R7 F1 R6 F1 R20 E3 R3
1110 DRAW "BM133,101 E5 R2 E3 U4 R1 E1 R7 F1 R5 F1 R16 F1 R8 F1 R21 E5 H3 U2 E4 L10 H2 U1 R1 D1 R2 U4 L2 D1 L1 U2 R2 E5 U3 E7 U8 F8 D5 G2 D2 R16 E3 U2 H9 U7 E4
1120 DRAW "BM235,40 R4 E1 R6 F1 R6 F3 D2 F3 R5 E1 U11 E4 R6 D1 L1 D2 R4 U2 L1 U1 R4 D8 F8 R5 U4 E2 U19 L3 U2 R2 E1 U8 E1 U7 E4":DRAW "BG70":DRAW "BL65":DRAW "P1,3":DRAW "C3"
1130 DRAW "BM313,0 G3 D4 F1 R2 D1 L1 D2 R4 U2 L1 U1 R4":DRAW "BH3":DRAW "P1,3"
1150 LAX=47:LAY=96:GOSUB 100
1160 LAX=128:LAY=104:GOSUB 100
1170 LAX=144:LAY=89:GOSUB 100
1180 LFX=128:LFY=152:GOSUB 106
1190 LFX=136:LFY=168:GOSUB 106
1200 LFX=152:LFY=120:GOSUB 106
1210 LFX=168:LFY=104:GOSUB 106
1220 LFX=200:LFY=96:GOSUB 106
1230 LFX=264:LFY=40:GOSUB 106
1240 LFX=272:LFY=80:GOSUB 106
1250 LFX=288:LFY=56:GOSUB 106
1260 LFX=296:LFY=128:GOSUB 106
1270 LRX=40:LRY=128:GOSUB 114
1280 LRX=40:LRY=144:GOSUB 114
1290 LRX=136:LRY=128:GOSUB 114
1300 LRX=280:LRY=48:GOSUB 114
1310 LGX=40:LGY=104:GOSUB 130
1320 LGX=40:LGY=112:GOSUB 130
1330 LGX=48:LGY=112:GOSUB 130
1340 LGX=48:LGY=120:GOSUB 130
1350 LGX=56:LGY=120:GOSUB 130
1360 LGX=56:LGY=128:GOSUB 130
1370 LGX=64:LGY=128:GOSUB 130
1380 LGX=64:LGY=136:GOSUB 130
1390 LGX=64:LGY=144:GOSUB 130
1400 LGX=72:LGY=144:GOSUB 130
1410 LGX=104:LGY=136:GOSUB 130
1420 LGX=112:LGY=136:GOSUB 130
1430 LGX=112:LGY=128:GOSUB 130
1440 LGX=120:LGY=128:GOSUB 130
1450 LGX=120:LGY=120:GOSUB 130
1460 LGX=128:LGY=120:GOSUB 130
1470 LGX=128:LGY=112:GOSUB 130
1480 LGX=136:LGY=112:GOSUB 130
1490 LGX=136:LGY=104:GOSUB 130
1500 LGX=144:LGY=104:GOSUB 130
1505 LGX=144:LGY=96:GOSUB 130
1510 LGX=152:LGY=96:GOSUB 130
1520 LGX=152:LGY=88:GOSUB 130
1530 LGX=160:LGY=88:GOSUB 130
1540 LGX=168:LGY=88:GOSUB 130
1550 LGX=176:LGY=88:GOSUB 130
1560 LGX=184:LGY=88:GOSUB 130
1570 LGX=192:LGY=88:GOSUB 130
1580 LGX=248:LGY=88:GOSUB 130
1590 LGX=248:LGY=80:GOSUB 130
1600 LGX=248:LGY=72:GOSUB 130
1610 LGX=256:LGY=72:GOSUB 130
1620 LGX=256:LGY=64:GOSUB 130
1630 LGX=256:LGY=56:GOSUB 130
1640 LGX=256:LGY=48:GOSUB 130
1650 LGX=248:LGY=48:GOSUB 130
1660 LGX=248:LGY=40:GOSUB 130
1670 LGX=264:LGY=32:GOSUB 130
1680 LGX=296:LGY=0:GOSUB 130
1690 LGX=296:LGY=8:GOSUB 130
1700 LGX=296:LGY=16:GOSUB 130
1710 LGX=296:LGY=24:GOSUB 130
1712 LINE (159,143)-(319,143),2:LINE (159,143)-(159,199),2:PAINT (250,164),0,2
1713 LINE (0,17)-(137,17),2:LINE (137,17)-(137,0),2:PAINT (70,8),0,2:GOSUB 5010
1715 CHALT=0:'*AFTER SCR COPPIED*
1717 IF LALT=1 THEN ALT=ALT-5000
1720 GOSUB 2200:GOSUB 9000:LOCATE 19,21:PRINT SN$(LOGO):LOCATE 20,21:PRINT "CLOUD";W(1):LOCATE 20,28:PRINT;W(2)
1730 LOCATE 20,30:PRINT;W(3):LOCATE 20,32:PRINT;W(4):LOCATE 20,34:PRINT W(5):LOCATE 20,36:PRINT W(6):LOCATE 20,38:PRINT;W(7)
1731 PRESET (108+VX,52+VY)
1740  LOCATE 21,21:PRINT "ALTITUDE";ALT;"     ":LOCATE 22,21:PRINT "FUEL";FUEL;"GAL   ":LOCATE 23,21:PRINT BL$;BOMBS:LOCATE 1,1:PRINT TARGET$
1750 LET FSTP=1:IF ALT=0 AND PLOTX=14 AND PLOTY=7 THEN 31110
1760 CIRCLE (((TX*8)-4),((TY*8)-4)),2:CIRCLE (((TX*8)-4),((TY*8)-4)),1
2000 '*
2008 ACT$=INKEY$:LOCATE 22,21:PRINT "FUEL";FUEL;"GAL":IF FUEL < 1 THEN ALT=ALT-5000:FOR I=1 TO 300:NEXT I
2009 IF ACT$="R" OR ACT$="r" THEN GOSUB 14000
2010 IF ACT$="1" THEN PLOTY=PLOTY-1:GOSUB 94:FUEL=FUEL-30:GOTO 2110
2020 IF ACT$="2" THEN PLOTY=PLOTY-1:PLOTX=PLOTX+1:GOSUB 95:FUEL=FUEL-42:GOTO 2120
2030 IF ACT$="3" THEN PLOTX=PLOTX+1:GOSUB 91:FUEL=FUEL-30:GOTO 2130
2040 IF ACT$="4" THEN PLOTX=PLOTX+1:PLOTY=PLOTY+1:GOSUB 80:FUEL=FUEL-42:GOTO 2140
2050 IF ACT$="5" THEN PLOTY=PLOTY+1:GOSUB 93 :FUEL=FUEL-30:GOTO 2150
2060 IF ACT$="6" THEN PLOTX=PLOTX-1:PLOTY=PLOTY+1:GOSUB 83:FUEL=FUEL-42:GOTO 2160
2070 IF ACT$="7" THEN PLOTX=PLOTX-1:GOSUB 92:FUEL=FUEL-30:GOTO 2170
2080 IF ACT$="8" THEN PLOTX=PLOTX-1:PLOTY=PLOTY-1:GOSUB 86:FUEL=FUEL-42:GOTO 2180
2081 PSET (108+VX,52+VY)
2090 IF ACT$="0" THEN FUEL=FUEL-25:FOR Q=1 TO 4:GOSUB 13000:NEXT Q:BEEP:GOSUB 9000:GOTO 1715
2091 IF CHALT=1 THEN 2095
2092 IF ALT=35000! THEN 2094
2093 IF ACT$="U" OR ACT$="u" THEN ALT=ALT+5000:FUEL=FUEL-15:CHALT=1
2094 IF ACT$="D" OR ACT$="d" THEN ALT=ALT-5000:FUEL=FUEL+10:CHALT=1
2095 IF ALT<1 THEN GOTO 31110
2096 IF ACT$="A" OR ACT$="a" THEN GOSUB 30010:TA=-1:B=1
2098 IF ACT$="S" OR ACT$="s" THEN GOSUB 30000
2099 IF ACT$="B" OR ACT$="b" THEN CALL ML1:CLS:GOTO 31312
2100 GOTO 1730
2110 IF ER=1 THEN ER=0:GOTO 2000
2111 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2112 IF ALT=TA THEN PSET (106+VX,53+VY):PSET (110+VX,53+VY)
2113 OVER=POINT ((108+VX),(51+VY)):VY=VY-2:GOSUB 13000:NEXT Q:BEEP
2119  GOTO 1715
2120 IF ER=1 THEN ER=0:GOTO 2000
2121 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2122 IF ALT=TA THEN PSET (106+VX,52+VY):PSET (108+VX,54+VY)
2123 OVER=POINT ((109+VX),(51+VY)):VX=VX+2:VY=VY-2:GOSUB 13000:NEXT Q:BEEP
2129 GOTO 1715
2130 IF ER=1 THEN ER=0:GOTO 2000
2131 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2132 IF ALT=TA THEN PSET (107+VX,50+VY):PSET (107+VX,54+VY)
2133 OVER=POINT ((109+VX),(52+VY)):VX=VX+2:GOSUB 13000:NEXT Q:BEEP
2139 GOTO 1715
2140 IF ER=1 THEN ER=0:GOTO 2000
2141 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2142 IF ALT=TA THEN PSET (106+VX,52+VY):PSET (108+VX,50+VY)
2143 OVER=POINT ((109+VX),(53+VY)):VX=VX+2:VY=VY+2:GOSUB 13000:NEXT Q:BEEP
2149 GOTO 1715
2150 IF ER=1 THEN ER=0:GOTO 2000
2151 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2152 IF ALT=TA THEN PSET (106+VX,51+VY):PSET (110+VX,51+VY)
2153 OVER=POINT ((108+VX),(53+VY)):VY=VY+2:GOSUB 13000:NEXT Q:BEEP
2159 GOTO 1715
2160 IF ER=1 THEN ER=0:GOTO 2000
2161 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2162 IF ALT=TA THEN PSET (108+VX,50+VY):PSET (110+VX,52+VY)
2163 OVER=POINT ((107+VX),(53+VY)):VX=VX-2:VY=VY+2:GOSUB 13000:NEXT Q:BEEP
2169 GOTO 1715
2170 IF ER=1 THEN ER=0:GOTO 2000
2171 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2172 IF ALT=TA THEN PSET (109+VX,50+VY):PSET (109+VX,54+VY)
2173 OVER=POINT ((107+VX),(51+VY)):VX=VX-2:GOSUB 13000:NEXT Q:BEEP
2179 GOTO 1715
2180 IF ER=1 THEN ER=0:GOTO 2000
2181 FOR Q=1 TO 4:PSET (108+VX,52+VY)
2182 IF ALT=TA THEN PSET (108+VX,54+VY):PSET (110+VX,52+VY)
2183 OVER=POINT ((107+VX),(51+VY)):VX=VX-2:VY=VY-2:GOSUB 13000:NEXT Q:BEEP
2189 GOTO 1715
2200 '*
2210 IF CHALT=1 THEN RETURN
2215 IF PLOTY<8 THEN WX=3
2220 GOSUB 166:IF RN<4+WX THEN W(1)=W(1)+1
2230 IF RN>50 THEN W(1)=W(1)-1
2240 IF W(1)<0 THEN W(1)=0
2250 GOSUB 166:IF RN<6+WX THEN W(2)=W(2)+1
2260 IF RN>60 THEN W(2)=W(2)-1
2270 IF W(2)<0 THEN W(2)=0
2280 GOSUB 166:IF RN<7+WX THEN W(3)=W(2)+1
2290 IF RN>60 THEN W(3)=W(3)-1
2300 IF W(3)<0 THEN W(3)=0
2310 GOSUB 166:IF RN<5+WX THEN W(4)=W(4)+1
2320 IF RN>60 THEN W(4)=W(4)-1
2330 IF W(4)<0 THEN W(4)=0
2340 GOSUB 166:IF RN<4+WX THEN W(5)=W(5)+1
2350 IF RN>50 THEN W(5)=W(5)-1
2360 IF W(5)<0 THEN W(5)=0
2370 GOSUB 166:IF RN<3+WX THEN W(6)=W(6)+1
2380 IF RN>50 THEN W(6)=W(6)-1
2390 IF W(6)<0 THEN W(6)=0
2400 GOSUB 166:IF RN<2+WX THEN W(7)=W(7)+1
2410 IF RN>50 THEN W(7)=W(7)-1
2420 IF W(7)<0 THEN W(7)=0
2430 LOCATE 20,21:PRINT"CLOUD";W(1):LOCATE 20,28: PRINT;W(2):LOCATE 20,30:PRINT;W(3):LOCATE 20,32:PRINT;W(4):LOCATE 20,34:PRINT W(5):LOCATE 20,36:PRINT W(6):LOCATE 20,38:PRINT;W(7)
2440 RETURN
4008 IF Y$="O" THEN SS=2
5000 '*
5010 '*
5011 IF SHAPE=1 THEN CHALT=0:GOTO 6000
5013 LOCATE 1,1:PRINT "                 ":CALL ML1:CLS
5020 DRAW "C2":DRAW "BM158,70 F3 D7 R4 U4 E1 R2 F1 D5 R4 U4 E1 R2 F1 D5 R6 F1 R5 F1 R5 F1 D2 G1 L4 G1 L5 G1 L5 G1 L5 G1 L5 G1 L5 D7 G1 D6 F1 R5 F1 R5 F1 D2 G1 L13 D2 G1
5025 DRAW "BM158,70 G3 D7 L4 U4 H1 L2 G1 D5 L4 U4 H1 L2 G1 D5 L6 G1 L5 G1 L5 G1 D2 F1 R4 F1 R5 F1 R5 F1 R5 F1 R5 F1 R5 D7 F1 D6 G1 L5 G1 L5 G1 D2 F1 R13 D2 F1":DRAW "BM158,89":DRAW "P1,2"
5026 DRAW "C2":DRAW "BM158,79 BL2 U2 E2 F2 D2 BD2 BL1 G1 H1 E1 F1 BD9 BR1 D3 L4 U3"
5028 IF REF=1 THEN:GET (119,75)-(154,93),B17A:GET (162,75)-(196,93),B17B:GET (155,70)-(161,107),B17C:GET (143,108)-(173,116),B17D:GET(119,70)-(196,116),B17:GOTO 5999
5030 DIM B17A(88):GET (119,75)-(154,93),B17A:DIM B17B(88):GET (162,75)-(196,93),B17B:DIM B17C(40):GET (155,70)-(161,107),B17C:DIM B17D(38):GET (143,108)-(173,116),B17D
5032 DIM B17(449):GET (119,70)-(196,116),B17
5040 DIM B17AS(88):GET (119,75)-(154,93),B17AS:DIM B17BS(88):GET (162,75)-(196,93),B17BS:DIM B17CS(40):GET (155,70)-(161,107),B17CS:DIM B17DS(38):GET (143,108)-(173,116),B17DS:CLS
5050 '*
5060 DRAW "C2":DRAW "BM188,45 F2 G2 H2 E2 BD1":DRAW "P2,2"
5090 '*
5100 DRAW "C3":DRAW "BM188,41 F3 R2 D1 G2 D1 F1 D3 L1 G3 H1 L2 G1 L2 H1 L1 H1 U1 E1 H2 U1 E2 H1 E2 R2 E2 R2"
5110 DRAW "BM188,48":DRAW "P3,3"
5120 DIM SMOKE(120)
5130 GET (177,41)-(195,55),SMOKE:CLS
5200 '*
5210 LGX=201:LGY=24:GOSUB 130:LGX=206:LGY=17:GOSUB 130:LGX=216:LGY=19:GOSUB 130 :LGX=224:LGY=23:GOSUB 130
5220 DIM AABT(66):GET (200,17)-(232,32),AABT:CLS
5230 '*ME109U SHAPE*
5240 DRAW "C2":DRAW "BM201,107 E1 R10 U4 E1 F1 D4 R10 F1 G2 L7 G2 D4 R3 D2 L2 H1 G1 H1 G1 L2 U2 R3 U4 H2 L7 H2 BR12":DRAW "P1,2":LINE (210,116)-(216,116),1:LINE (213,107)-(213,110),3
5250 DIM ME109U(62):GET (201,101)-(225,117),ME109U:CLS
5255 '*
5260 DRAW "C2":DRAW "BM201,111 E2 R7 E2 U4 L3 U2 R2 F1 E1 F1 E1 R2 D2 L3 D4 F2 R7 F2 G1 L10 D4 G1 H1 U4 L10 H1 BR12 ":DRAW "P1,2":LINE (210,102)-(216,102),1:LINE (213,108)-(213,111),3
5270 DIM ME109D (62):GET (201,101)-(225,117),ME109D:CLS
5280 '*
5290 DRAW "C2":DRAW "BM203,75 R17 E1 U3 H1 G3 L4 H1 L4 G1 L5 G1 R1 BR5":DRAW "P1,2":DIM ME109L(20):GET (201,70)-(221,75),ME109L:CLS
5300 '*ME109R SHAPE*
5310 DRAW "C2":DRAW "BM201,74 F1 R17 E1 R1 H1 L5 H1 L4 G1 L4 H3 G1 D2 BR1":DRAW "P1,2":DIM ME109R(20):GET (201,70)-(221,75),ME109R:CLS
5330 '*FW 190U SHAPE*
5340 DRAW "C2":DRAW "BM201,107 F1 R10 D7 L4 D2 R10 U2 L4 U7 R10 E1 U1 H1 L10 U4 L2 D4 L10 G1 BR11":DRAW "P1,2":LINE (213,107)-(213,109):LINE (213,114)-(213,117)
5350 DIM FW190U(62):GET (201,101)-(225,117),FW190U:CLS
5360 '*FW 190D SHAPE*
5370 DRAW "C2":DRAW "BM201,112 F1 R10 D4 R2 U4 R10 E1 U1 H1 L10 U7 R4 U2 L10 D2 R4 D7 L10 G1 BR11":DRAW "P1,2":LINE (213,101)-(213,104):LINE (213,109)-(213,111)
5380 DIM FW190D(62):GET (201,101)-(225,117),FW190D:CLS
5390 '*FW 190L SHAPE*
5400 DRAW "C2":DRAW "BM201,75 R19 E1 U3 H1 G3 L5 H1 L3 G1 L6 D1 BR9":DRAW "P1,2":DIM FW190L(20):GET (201,70)-(221,75),FW190L:CLS
5410 '*FW 190R SHAPE*
5420 DRAW "C2":DRAW "BM202,75 R19 U2 L6 H1 L3 G1 L5 H3 G1 D3 BR9":DRAW "P1,2":DIM FW190R(20):GET (201,70)-(221,75),FW190R:CLS
5430 '*ME110U SHAPE*
5440 DRAW "C2":DRAW "BM201,80 R7 F1 R5 F1 D8 L4 D2 R10 U2 L4 U8 E1 R5 E1 R7 U2 L4 H1 L3 H1 U2 H1 G1 D1 G1 L2 U4 H1 G1 D4 L2 H1 U1 H1 G1 D2 G1 L3 G1 L4 D2 BR15"
5450 DRAW "P1,2":DIM ME110U(90):GET (201,71)-(231,92),ME110U:CLS
5460 '*ME110D*
5470 DRAW "C2":DRAW "BM201,85 R4 F1 R3 F1 D2 F1 E1 U1 E1 R2 D4 F1 E1 U4 R2 F1 D1 F1 E1 U2 E1 R3 E1 R4 U2 L7 H1 L5 H1 U8 R4 U2 L10 D2 R4 D8 G1 L5 G1 L7 D1 BR15"
5480 DRAW "P1,2":DIM ME110D(90):GET (201,71)-(231,92),ME110D:CLS
5490 '*ME110L SHAPE*
5500 DRAW "C2":DRAW "BM201,74 F1 R21 F1 E1 U3 H1 G1 D1 L13 H1 L4 G1 L2 BD1 BR12":DRAW "P1,2":DIM ME110L(23):GET (201,71)-(225,76),ME110L:CLS
5510 '*ME110R SHAPE*
5520 DRAW "C2":DRAW "BM201,72 F1 R13 E1 R4 F1 R2 F1 G1 L21 G1 H1 U2 BF1 BR12":DRAW "P1,2":DIM ME110R(23):GET (201,71)-(225,76),ME110R:CLS
5530 '*FLASH SHAPE*
5540 DRAW "C2":DRAW "BM200,100 BR2 R3 F1 D1 F1 G2 D2 L3 H1 U1 H1 U1 E3 BD2":DRAW "P2,2":DIM FLA(10):GET (200,100)-(207,107),FLA:CLS
5990 REF=1
5999 SHAPE=1:CLS:GOSUB 31010:CALL ML2:RETURN
6000 '*
6002 COLOR 0,CL:CALL ML1:CLS
6010 PUT (119,75),B17A,XOR:PUT (162,75),B17B,XOR:PUT (155,70),B17C,PSET:PUT (143,108),B17D,XOR:GOSUB 15000
6015 IF ALT=TA THEN PUT (5,150),B17,PSET:PUT (233,150),B17,PSET
6020 HFLACK=HFLACK+10
6021 IF ALT=5000 THEN HFLACK=HFLACK+30
6022 IF ALT=10000 THEN HFLACK=HFLACK+10
6023 IF ALT=15000 THEN HFLACK=HFLACK+5
6024 IF ALT=25000 THEN HFLACK=HFLACK-5
6025 IF ALT>25000 THEN HFLACK=HFLACK-10
6026 LOCATE 1,1
6030 FOR S=1 TO HFLACK:GOSUB 12:PUT (200,(25+MY)),AABT,XOR:GOSUB 168:GOSUB 171:GOSUB 176:IF FHRN>160 THEN 6032
6031 GOSUB 10000
6032 GOSUB 26
6044 PUT (200,(25+MY)),AABT,XOR:MY=MY+2:NEXT S: HFLACK=0
6060 GET (119,75)-(154,93),B17A:GET (162,75)-(196,93),B17B:GET (155,70)-(161,107),B17C:GET (143,108)-(173,116),B17D:MY=0
6520 FOR I=1 TO 2000:NEXT I:HFLACK=0:CLS:COLOR 0,CL:CALL ML2:RETURN
9000 '*
9001 IF W(1)>0 THEN RETURN
9002 CC=0:IF ALT>=5000 THEN FOR X=1 TO ALT/5000:CC=CC+W(X):NEXT X
9003 IF CC>0 THEN RETURN
9004 IF ALT>25000 THEN RETURN
9010 IF PLOTX=38 AND PLOTY=1 THEN 5010
9020 IF PLOTX = 38 AND PLOTY = 2 THEN 5010
9030 IF PLOTX=40 AND PLOTY=2 THEN 5010
9040 IF PLOTX=38 AND PLOTY=3 THEN 5010
9050 IF PLOTX=38 AND PLOTY=4 THEN 5010
9060 IF PLOTX=34 AND PLOTY=5 THEN 5010
9070 IF PLOTX=35 AND PLOTY=5 THEN HFLACK=HFLACK+10:HP=HP+15:GOTO 5010
9080 IF PLOTX=32 AND PLOTY=6 THEN 5010
9090 IF PLOTX=34 AND PLOTY=6 THEN 5010
9100 IF PLOTX=32 AND PLOTY=7 THEN 5010
9110 IF PLOTX=33 AND PLOTY=7 THEN 5010
9120 IF PLOTX=36 AND PLOTY=7 THEN HFLACK=HFLACK+10:HP=HP+15:GOTO 5010
9130 IF PLOTX=33 AND PLOTY=8 THEN 5010
9135 IF PLOTX=37 AND PLOTY=8 THEN 5010
9140 IF PLOTX=33 AND PLOTY=9 THEN 5010
9150 IF PLOTX=32 AND PLOTY=10 THEN 5010
9160 IF PLOTX=33 AND PLOTY=10 THEN 5010
9170 IF PLOTX =32 AND PLOTY=11 THEN 5010
9180 IF PLOTX=35 AND PLOTY=11 THEN 5010
9190 IF PLOTX=19 AND PLOTY=12 THEN 5010
9200 IF PLOTX=20 AND PLOTY=12 THEN 5010
9210 IF PLOTX=21 AND PLOTY=12 THEN 5010
9215 IF PLOTX=22 AND PLOTY=12 THEN 5010
9220 IF PLOTX=23 AND PLOTY=12 THEN 5010
9230 IF PLOTX=24 AND PLOTY=12 THEN 5010
9240 IF PLOTX=25 AND PLOTY=12 THEN 5010
9245 IF PLOTX=32 AND PLOTY=12 THEN 5010
9250 IF PLOTX=7 AND PLOTY=13 THEN 5010
9260 IF PLOTX=19 AND PLOTY=13 THEN 5010
9270 IF PLOTX=20 AND PLOTY=13 THEN 5010
9280 IF PLOTX=26 AND PLOTY=13 THEN 5010
9285 IF PLOTX=26 AND PLOTY=10 THEN 5010
9290 IF PLOTX=6 AND PLOTY=14 THEN 5010
9300 IF PLOTX=17 AND PLOTY=14 THEN 5010
9310 IF PLOTX=18 AND PLOTY=14 THEN 5010
9320 IF PLOTX=19 AND PLOTY=14 THEN 5010
9330 IF PLOTX=22 AND PLOTY=14 THEN 5010
9340 IF PLOTX=6 AND PLOTY=15 THEN 5010
9350 IF PLOTX=7 AND PLOTY=15 THEN 5010
9360 IF PLOTX=17 AND PLOTY=15 THEN 5010
9370 IF PLOTX=18 AND PLOTY=15 THEN 5010
9380 IF PLOTX=1 AND PLOTY=16 THEN 5010
9390 IF PLOTX=7 AND PLOTY=16 THEN 5010
9400 IF PLOTX=8 AND PLOTY=16 THEN 5010
9410 IF PLOTX=16 AND PLOTY=16 THEN 5010
9420 IF PLOTX=17 AND PLOTY=16 THEN 5010
9430 IF PLOTX=20 AND PLOTY=16 THEN 5010
9440 IF PLOTX=6 AND PLOTY=17 THEN 5010
9450 IF PLOTX=8 AND PLOTY=17 THEN 5010
9460 IF PLOTX=9 AND PLOTY=17 THEN 5010
9470 IF PLOTX=15 AND PLOTY=17 THEN 5010
9480 IF PLOTX=16 AND PLOTY=17 THEN 5010
9490 IF PLOTX=18 AND PLOTY=17 THEN 5010
9500 IF PLOTX=38 AND PLOTY=17 THEN 5010
9510 IF PLOTX=9 AND PLOTY=18 THEN 5010
9520 IF PLOTX=14 AND PLOTY=18 THEN 5010
9530 IF PLOTX=15 AND PLOTY=18 THEN 5010
9540 IF PLOTX=6 AND PLOTY=19 THEN 5010
9550 IF PLOTX=9 AND PLOTY=19 THEN 5010
9560 IF PLOTX=10 AND PLOTY=19 THEN 5010
9570 IF PLOTX=3 AND PLOTY=20 THEN HFLACK=HFLACK+10:HP=HP+15:GOTO 5010
9580 IF PLOTX=17 AND PLOTY=20 THEN 5010
9590 IF PLOTX=4 AND PLOTY=22 THEN 5010
9592 IF PLOTX=18 AND PLOTY=22 THEN 5010
9594 IF PLOTX=4 AND PLOTY=25 THEN HFLACK=HFLACK+10:HP=HP+15:GOTO 5010
9596 RETURN
10000 '*
10002 LOCATE 2,1:PRINT "                                                                               ":LOCATE 2,1
10003 GOSUB 166:IF RN<4 THEN GOSUB 12:PRINT "THAT WAS CLOSE !":GOTO 10017
10004 IF RN<7 AND RN>3 THEN GOSUB 12:PRINT "BOY! I THOUGHT THAT HAD OUR NUMBER !":GOTO 10017
10005 IF RN<10 AND RN>6 THEN GOSUB 12:PRINT "EVERYBODY OK ?":GOTO 10017
10007 IF RN<13 AND RN>9 THEN GOSUB 12:PRINT "I THOUGHT WE BOUGHT THE FARM THAT TIME !":GOTO 10017
10008 IF RN<16 AND RN>12 THEN GOSUB 12:PRINT "BOY WERE WE LUCKY !":GOTO 10017
10009 IF RN<19 AND RN>15 THEN GOSUB 12:PRINT "NOT THIS TIME BABY !":GOTO 10017
10010 IF RN<25 AND RN>18 THEN PRINT "THAT'S CLOSE ENOUGH !":GOTO 10017
10016 GOTO 10018
10017 GOSUB 12:FXRN=151:FYRN=64:GOSUB 27:RETURN
10018 GOSUB 174:IF DRN=1 THEN PRINT "NORDEN SIGHT HIT":OT=OT-.4:LET FXRN=151:FYRN=63:PRESET (158,71):RETURN
10020 IF DRN=2 THEN 10040
10030 GOTO 10100
10040 GOSUB 164:IF C(1)>1 THEN 10100
10050 IF RN<16 THEN PRINT CB$;C1$:AA=1:FXRN=149:FYRN=65:PRESET (157,72):RETURN
10060 IF RN<31 AND RN>15 THEN PRINT CB$;C2$:B(1)=1:FXRN =150:FYRN=64:PRESET (158,72):RETURN
10070 IF RN<61 AND RN>30 THEN PRINT NB$;C3$:BB=1:OT=OT-.2:C(1)=C(1)+1:FXRN =151:FYRN=65:PRESET (159,72):RETURN
10080 IF RN<86 AND RN>60 THEN PRINT NB$;C4$:OT=OT-.2:G(1)=0:GP=GP-300:C(1)=3:FXRN=152:FYRN=64:PRESET (156,73):RETURN
10090 IF RN>85 THEN PRINT NB$;C5$:OT=OT+.7:GP=GP-500:C(1)=3:FXRN=153:FYRN=65:PRESET (158,73):RETURN
10100 IF DRN=3 THEN 10120
10110 GOTO 10160
10120 GOSUB 164
10130 IF RN<41 THEN PRINT "NOSE GUN HIT":G(1)=0:FXRN=151:FYRN=71:PRESET (160,73):RETURN
10140 IF RN<71 AND RN>40 THEN PRINT "PORT CHEEK GUN":G(2)=0:FXRN=148:FYRN=67:PRESET (156,74):RETURN
10150 IF RN>70 THEN PRINT "STARBORD CHEEK GUN":G(3)=0:FXRN=154:FYRN=67:PRESET (160,74):RETURN
10160 IF DRN=4 THEN PRINT "FIRE IN THE NOSE":F(5)=1:FIRE=1:FXRN=151:FYRN=72:PRESET  (158,74):GOSUB 12000:RETURN
10170 IF DRN=5 THEN GOTO 10190
10180 GOTO 10250
10190 GOSUB 164:IF C(2)>1 THEN 10250
10200 IF RN<16 THEN PRINT CN$;C1$:AA=1:FXRN=150:FYRN=70:PRESET (158,75):RETURN
10210 IF RN<31 AND RN>15 THEN PRINT CN$;C2$:B(2)=1:FXRN=151:FYRN=70:PRESET (157,73):RETURN
10220 IF RN<61 AND RN>30 THEN PRINT NC$;C3$:RX=RX+5:C(2)=C(2)+1:FXRN=158:FYRN=70:PRESET (159,73):RETURN
10230 IF RN<86 AND RN>60 THEN PRINT NC$;C4$:G(2)=0:G(3)=0:GP=GP-300:C(2)=3 :FXRN=157:FYRN=70:PRESET (157,74):RETURN
10240 IF RN>85 THEN PRINT NC$;C5$:RX=RX+10:G(2)=0:G(3)=0:GP=GP-500:C(2)=3:FXRN=157:FYRN=69:PRESET (160,73):RETURN
10250 IF DRN=6 THEN PRINT "BOMB CONTROLS HIT":OT=OT-.3:FXRN=153:FYRN=69:PRESET (159,74):RETURN
10260 IF DRN=7 THEN PRINT "CONTROLS DAMAGED":LD=LD+5:FXRN=152:FYRN=71:PRESET (157,75):RETURN
10270 IF DRN=8 THEN PRINT "AUTO PILOT OUT":OT=OT-.2:LD=LD+2:FXRN=153:FYRN=70:PRESET (159,75):RETURN
10280 IF DRN=9 THEN PRINT "PANEL FIRE":F(5)=1:FIRE=1:FXRN=154:FYRN=71:PRESET (156,76):GOSUB 12000:RETURN
10290 IF DRN=10 THEN 10310
10300 GOTO 10370
10310 GOSUB 166
10320 IF RN<16 THEN PRINT CA$;C1$:AA=1:FXRN=149:FYRN=70:PRESET (157,77):RETURN
10330 IF RN<31 AND RN>15 THEN PRINT CA$;C2$:B(3)=1:FXRN=150:FYRN=70:PRESET (158,76):RETURN
10340 IF RN<61 AND RN>30 THEN PRINT CA$;C3$:LD=LD+2:PP=2:FXRN=149:FYRN=71:PRESET (156,78):RETURN
10350 IF RN<86 AND RN>60 THEN GOSUB 166:IF RN>75 THEN PRINT CA$;C4$:GP=GP-300:PP=1:FXRN=150:FYRN=71:PRESET (158,77):RETURN
10360 IF RN>85 THEN GOSUB 166:IF RN>75 THEN PRINT CA$;C5$;"-";:GP=GP-500:PRINT "K I A":GOTO 31220
10362 IF RN>0 THEN FXRN=150:FYRN=71:PRESET (156,75):RETURN
10370 IF DRN=11 THEN PRINT "CONTROLS DAMAGED":LD=LD+2:FXRN=151:FYRN=76:PRESET (160,76):RETURN
10380 IF DRN=12 THEN GOTO 10400
10390 GOTO 10460
10400 GOSUB 166:IF C(3)>1 THEN 10460
10410 IF RN<16 THEN PRINT CC$;C1$:AA=1:FXRN=155:FYRN=70:PRESET (160,75):RETURN
10420 IF RN<31 AND RN>15 THEN PRINT CC$;C2$:B(4)=1:FXRN=152:FYRN=69:PRESET (158,78):RETURN
10430 IF RN<61 AND RN>30 THEN PRINT NJ$;C3$:C(3)=C(3)+1:FXRN=155:FYRN=70:PRESET (159,79):RETURN
10440 IF RN<86 AND RN>60 THEN PRINT NJ$;C4$:GP=GP-300:C(3)=3:FXRN=153:FYRN =77:PRESET (159,77):RETURN
10450 IF RN >85 THEN PRINT NJ$;C5$:GP=GP-500:C(3)=3:FXRN=152:FYRN=71:PRESET (159,78):RETURN
10460 IF DRN=13 THEN PRINT "TOP TURRET HIT":G(4)=0:FXRN=151:FYRN=76:PRESET (158,81):RETURN
10470 IF DRN=14 THEN 10490
10480 GOTO 10550
10490 GOSUB 166:IF C(4)>1 THEN 10550
10500 IF RN<16 THEN PRINT CE$;C1$:AA=1:FXRN=149:FYRN=75:PRESET (158,79):RETURN
10510 IF RN<31 AND RN>15 THEN PRINT CE$;C2$:B(5)=1:FXRN=153:FYRN=75:PRESET (160,81):RETURN
10520 IF RN<61 AND RN>30 THEN PRINT ND$;C3$:C(4)=C(4)+1:FXRN=150:FYRN=76:PRESET (157,81):RETURN
10530 IF RN<86 AND RN>60 THEN PRINT ND$;C4$:G(4)=0:GP=GP-300:C(4)=3:FXRN=152:FYRN=76:PRESET (159,81):RETURN
10540 IF RN>85 THEN PRINT ND$;C5$:G(4)=0:GP=GP-500:C(4)=3:FXRN=151:FYRN=76:PRESET (157,81):RETURN
10550 IF DRN=15 THEN PRINT "FIRE IN THE COCKPIT":FIRE=1:GOSUB 12000:FXRN=152:FYRN=73:PRESET (157,79):RETURN
10560 IF DRN=16 THEN 10580
10570 GOTO 10610
10580 GOSUB 166:IF E(1)>0 THEN 10670
10590 IF RN<71 THEN PRINT "#1 ENGINE FEATHERED":E(1)=1:FXRN=131:FYRN=78:PRESET (140,78):LINE (138,75)-(144,75),3:RETURN
10600 IF RN>70 THEN PRINT "#1 ENGINE WINDMILLING":E(1)=1.5:FXRN=135:FYRN=78:PRESET (142,78):LINE (138,75)-(144,75),1:RETURN
10610 IF DRN=17 THEN 10630
10620 GOTO 10660
10630 GOSUB 166
10640 IF RN<91 THEN PRINT "#1 ENGINE FIRE":FXRN=136:FYRN=74:PRESET (140,80):GOTO 12240
10650 IF RN>90 THEN PRINT "#1 ENGINE RUNAWAY":PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
10655 IF DRN=18 AND E(1)>0 THEN RETURN
10660 IF DRN=18 THEN PRINT "1 ENGINE OIL LEAK":LINE (141,81)-(141,90),0:GOSUB 166:O(1)=INT(RN/10)+1:FXRN=136:FYRN=74:RETURN
10670 IF DRN=19 THEN 10690
10680 GOTO 10720
10690 GOSUB 166:IF E(2)>0 THEN 10780
10700 IF RN<71 THEN PRINT "#2 ENGINE FEATHERED":E(2)=1:FXRN=142:FYRN=71:PRESET (148,77):LINE (146,74)-(152,74),3:RETURN
10710 IF RN>70 THEN PRINT "#2 ENGINE WINDMILLING":E(2)=1.5:FXRN=142:FYRN=71:PRESET (150,77): LINE (146,74)-(152,74),1:RETURN
10720 IF DRN=20 THEN 10740
10730 GOTO 10770
10740 GOSUB 166
10750 IF RN<91 THEN PRINT "#2 ENGINE FIRE":FXRN=146:FYRN=74:PRESET (148,79):GOTO 12290
10760 IF RN>90 THEN PRINT "#2 ENGINE RUNAWAY":PRINT:PRINT " BAIL OUT !!!!": GOTO 31310
10765 IF DRN=21 AND E(2)>0 THEN RETURN
10770 IF DRN=21 THEN PRINT "2 ENGINE OIL LEAK":LINE (149,80)-(149,91),0:GOSUB 166:O(2)=INT (RN/10)+1:FXRN=146:FYRN=74:RETURN
10780 IF DRN=22 THEN 10800
10790 GOTO 10830
10800 GOSUB 166:IF E(3)>0 THEN 10890
10810 IF RN<71 THEN PRINT "#3 ENGINE FEATHERED-";:E(3)=1:FXRN=160:FYRN=74:PRESET (168,77):LINE (164,74)-(170,74),3:RETURN
10820 IF RN>70 THEN PRINT "#3 ENGINE WINDMILLING":E(3)=1.5:FXRN=160:FYRN=74:PRESET (166,77):LINE (164,74)-(170,74),1:RETURN
10830 IF DRN=23 THEN 10850
10840 GOTO 10880
10850 GOSUB 166
10860 IF RN<91 THEN PRINT "#3 ENGINE FIRE":FXRN=160:FYRN=74:PRESET (168,79):GOTO 12340
10870 IF RN>90 THEN PRINT "#3 ENGINE RUNAWAY":PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
10875 IF DRN=24 AND E(3)>0 THEN RETURN
10880 IF DRN=24 THEN PRINT "3 ENGINE OIL LEAK":LINE (167,80)-(167,91),0:GOSUB 166:O(3)=INT(RN/10)+1:FXRN=160:FYRN=74:RETURN
10890 IF DRN=25 THEN 10910
10900 GOTO 10940
10910 GOSUB 166:IF E(4)>0 THEN 11000
10920 IF RN<71 THEN PRINT "#4 ENGINE FEATHERED":E(4)=1:FXRN=168:FYRN=78:PRESET (176,78):LINE (172,75)-(178,75),3:RETURN
10930 IF RN>70 THEN PRINT "#4 ENGINE WINDMILLING-";:E(4)=1.5:FXRN=168:FYRN=78:PRESET (174,78):LINE (172,75)-(178,75),1:RETURN
10940 IF DRN=26 THEN 10960
10950 GOTO 10990
10960 GOSUB 166
10970 IF RN<91 THEN PRINT "#4 ENGINE FIRE":FXRN=168:FYRN=74:PRESET (173,80):GOTO 12390
10980 IF RN>90 THEN PRINT "#4 ENGINE RUNAWAY":PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
10985 IF DRN=27 AND E(4)>0 THEN RETURN
10990 IF DRN=27 THEN PRINT "4 ENGINE OIL LEAK":LINE (175,81)-(175,90),0:GOSUB 166:O(4)=INT(RN/10)+1:FXRN=168:FYRN=74:RETURN
11000 IF DRN >27 AND DRN<32 THEN GOSUB 180:PRESET (154,(81+RN)):PRINT "L. WING ROOT HIT":LR=LR+1:FXRN=147:FYRN=74
11010 IF LR>2 THEN PUT (119,75),B17A,XOR:FOR L = 1 TO 50:PUT ((119-L),(75+L)),B17A,XOR:FOR I=1 TO 20:NEXT I:PUT ((119-L),(75+L)),B17A,XOR:NEXT L:PRINT:PRINT "BAIL OUT !!!!":GOTO 31310
11020 IF DRN>31 AND DRN<36 THEN GOSUB 180:PRESET (162,(81+RN)):PRINT "R. WING ROOT HIT":RR=RR+1:FXRN=154:FYRN=74
11030 IF RR>2 THEN PUT (162,75),B17B,XOR:FOR L=1 TO 50:PUT ((162+L),(75+L)),B17B,XOR:FOR I=1 TO 20:NEXT I:PUT ((162+L),(75+L)),B17B,XOR:NEXT L:PRINT:PRINT "BAIL OUT !!!!":GOTO 31310
11040 IF DRN>35 AND DRN<39 THEN GOSUB 182:GOSUB 186:PRESET ((133+HRN),(84+VRN)):FXRN=126+HRN:FYRN=78+VRN:PRINT "FUEL TANK LEAK":FX=FX+3:GOSUB 166:IF RN>97 THEN PRINT:PRINT "FUEL TANK FIRE ! BAIL OUT !!!!":GOTO 31310
11050 IF DRN>38 AND DRN<42 THEN GOSUB 182:GOSUB 186:PRESET ((164+HRN),(84+VRN)):FXRN=158+HRN:FYRN=78+VRN:PRINT "FUEL TANK LEAK":FX=FX+3:GOSUB 166:IF RN>97 THEN PRINT:PRINT "FUEL TANK FIRE ! BAIL OUT !!!!":GOTO 31310
11060 IF DRN=42 THEN PRINT "LANDING GEAR HIT":LD=LD+20:FXRN=143:FYRN=76:PRESET (149,82):RETURN
11070 IF DRN=43 THEN PRINT "RAFT DESTROYED":FXRN=150:FYRN=84:PRESET (156,87):RX=RX+50:LRD=1:RETURN
11080 IF DRN>44 AND DRN<48 THEN PRINT "BOMB RELEASE DAMAGED":OT=OT-.2:FXRN = 151:FYRN=80:PRESET (157,86):RETURN
11090 IF DRN=48 THEN PRINT "BOMB BAY DOORS DAMAGED":B=2:OO=1:FXRN=154:FYRN=83:PRESET (158,86):BBD=1:RETURN
11100 IF DRN=49 THEN PRINT "CONTROLS DAMAGED":LD=LD+2:FXRN=150:FYRN=81:PRESET (156,87):RETURN
11110 GOSUB 166:IF RN>15 THEN 11130
11115 IF DRN=50 AND B>0 THEN DRN=48 GOTO 11090
11120 IF DRN=50 THEN GP=GP-4000:PRINT:PRINT "*** BOMBS DETONATE. CREW KIA":FOR I=1 TO 1500:NEXT I:GOTO 31220
11130 IF DRN=51 THEN PRINT "RADIO IS OUT":RX=RX+45:FXRN=153:FYRN=87:PRESET (157,89):RO=1:RETURN
11140 IF DRN=52 THEN 11160
11150 GOTO 11220
11160 GOSUB 164:FXRN=152:FYRN=91:IF C(5)>1 THEN 11220
11170 IF RN<16 THEN PRINT CR$;C1$:AA=1:PRESET (160,90):RETURN
11180 IF RN<31 AND RN>15 THEN PRINT CR$;C2$:B(6)=1:PRESET (157,90):RETURN
11190 IF RN<61 AND RN>30 THEN PRINT NI$;C3$:RX=RX+10:C(5)=C(5)+1:PRESET (159,90):RETURN
11200 IF RN<86 AND RN>60 THEN PRINT NI$;C4$:RX=RX+25:GP=GP-300:C(5)=3:PRESET (157,91):RETURN
11210 IF RN>85 THEN PRINT NI$;C5$:RX=RX+45:GP=GP-500:C(5)=3:PRESET (158,91):RETURN
11220 IF DRN=53 THEN PRINT "CONTROL DAMAGE":LD=LD+2:PRESET (159,92):RETURN
11230 IF DRN=54 THEN 11250
11240 GOTO 11310
11250 FXRN=151:FYRN=93:GOSUB 164:IF C(6)>1 THEN 11310
11260 IF RN<16 THEN PRINT CG$;C1$:AA=1:PRESET (158,96):RETURN
11270 IF RN<31 AND RN>15 THEN PRINT CG$;C2$:B(7)=1:PRESET (159,97):RETURN
11280 IF RN<61 AND RN>30 THEN PRINT NE$;C3$:C(6)=C(6)+1:PRESET (157,97):RETURN
11290 IF RN<86 AND RN>60 THEN PRINT NE$;C4$:G(7)=0:GP=GP-300:C(6)=3:PRESET (158,98):RETURN
11300 IF RN>85 THEN PRINT NE$;C5$:G(7)=0:GP=GP-500:C(6)=3:PRESET (158,97):RETURN
11310 IF DRN=55 THEN 11330
11320 GOTO 11390
11330 FXRN=149:FYRN=93:GOSUB 164:IF C(7)>1 THEN 11390
11340 IF RN<16 THEN PRINT CP$;C1$:AA=1:PRESET (156,95):RETURN
11350 IF RN<31 AND RN>15 THEN PRINT CP$;C2$:B(8)=1:PRESET (156,96):RETURN
11360 IF RN<61 AND RN>30 THEN PRINT NF$;C3$:C(7)=C(7)+1:PRESET (156,97):RETURN
11370 IF RN<86 AND RN>60 THEN PRINT NF$;C4$:G(5)=0:GP=GP-300:C(7)=3:PRESET(156,98):RETURN
11380 IF RN>85 THEN PRINT NF$;C5$:G(5)=0:GP=GP-500:C(7)=3:PRESET (156,99):RETURN
11390 IF DRN=56 THEN 11410
11400 GOTO 11470
11410 FXRN=161:FYRN=90:GOSUB 164:IF C(8)>1 THEN 11470
11420 IF RN<16 THEN PRINT CS$;C1$:AA=1:PRESET (160,95):RETURN
11430 IF RN<31 AND RN>15 THEN PRINT CS$;C2$:B(9)=1:PRESET (160,96):RETURN
11440 IF RN<61 AND RN>30 THEN PRINT NG$;C3$:C(8)=C(8)+1:PRESET (160,97):RETURN
11450 IF RN<86 AND RN>60 THEN PRINT NG$;C4$:G(6)=0:GP=GP-300:C(8)=3:PRESET (160,98):RETURN
11460 IF RN>85 THEN PRINT NG$;C5$:G(6)=0:GP=GP-500:C(8)=3:PRESET (160,99):RETURN
11470 IF DRN=57 THEN PRINT "BALL GUN OUT":G(7)=0:FXRN=151:FYRN=90:PRESET (158,95):RETURN
11480 IF DRN=58 THEN PRINT "PORT GUN OUT":G(5)=0:FXRN=148:FYRN=90:PRESET (156,100):RETURN
11490 IF DRN=59 THEN PRINT "STBD GUN OUT":G(6)=0:FXRN=153:FYRN=90:PRESET (160,100):RETURN
11500 IF DRN>59 AND DRN<62 THEN PRINT "CONTROL DAMAGE":LD=LD+2:FXRN=152:FYRN=100:PRESET (159,103):RETURN
11510 IF DRN>61 AND DRN<64 THEN PRINT "STABILIZER ROOT HIT":SR=SR+1:FXRN=152:FYRN=102:PRESET (157,107):IF SR=2 THEN PRESET (159,107)
11520 IF SR>2 THEN PRINT : PRINT "TAIL PLANE GONE !!! BAIL OUT !!!!" : PUT (143,108),B17D,XOR : FOR L = 1 TO 50 : PUT (143,(108+L)),B17D,XOR : FOR I = 1 TO 20 : NEXT I : PUT (143,(108+L)),B17D,XOR : NEXT L : GOTO 31310
11530 IF DRN=64 THEN 11550
11540 GOTO 11610
11550 FXRN=152:FYRN=102:GOSUB 164:IF C(9)>1 THEN 11610
11560 IF RN<16 THEN PRINT CT$;C1$:AA=1:PRESET (158,111):RETURN
11570 IF RN<31 AND RN>15 THEN PRINT CT$;C2$:B(10)=1:PRESET (158,112):RETURN
11580 IF RN<61 AND RN>30 THEN PRINT NH$;C3$:C(9)=C(9)+1:PRESET (158,113):RETURN
11590 IF RN<86 AND RN>60 THEN PRINT NH$;C4$:G(8)=0:GP=GP-300:C(9)=3:PRESET (158,114):RETURN
11600 IF RN>85 THEN PRINT NH$;C5$:G(8)=0:GP=GP-500:C(9)=3:PRESET (158,115):RETURN
11610 IF DRN=65 THEN PRINT "AUTO PILOT OUT":LD=LD+2:OT=OT-.2:FXRN=152:FYRN=102:PRESET (158,100):RETURN
11620 IF DRN=66 THEN PRINT "TAIL GUN OUT":G(8)=0:FXRN=152:FYRN=102:PRESET (158,115)
11630 RETURN
12000 '*
12010 GOSUB 154:LINE (158,118)-(158,135),2:FOR L=1 TO 63:FOR J=1 TO 5:NEXT J:PSET (158,(136+L)),3:NEXT L
12200 '*
12210 F$=INKEY$:IF F$<>"5" THEN 12210
12215 BEEP
12220 FX5=FX5+1:GOSUB 166:IF RN<81 THEN FIRE=0:LINE (158,118)-(158,135),0:FOR L=1 TO 63:FOR J=1 TO 5:NEXT J:PRESET (158,(136+L)):NEXT L:RETURN
12230 GOTO 12210
12240 '*
12250 GOSUB 154:LINE (141,92)-(141,109),2:FOR L=1 TO 88:FOR J=1 TO 5:NEXT J:PSET (141,(110+L)),3:NEXT L
12260 F$=INKEY$:IF F$<>"1" THEN 12260
12265 BEEP
12270 IF FX1=2 THEN PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
12280 FX1=FX1+1:GOSUB 166:IF RN<81 THEN FIRE=0:LINE (141,92)-(141,109),0:FOR L=1 TO 88:FOR J=1 TO 5:NEXT J:PRESET (141,(110+L)):NEXT L:RETURN
12285 GOTO 12260
12290 '*
12300 GOSUB 154:LINE (149,93)-(149,108),2:FOR L=1 TO 66:FOR J=1 TO 5:NEXT J:PSET (149,(114+L)),3:NEXT L
12310 F$=INKEY$:IF F$<>"2" THEN 12310
12315 BEEP
12320 IF FX2=2 THEN PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
12330 FX2=FX2+1:GOSUB 166:IF RN<81 THEN FIRE=0:LINE (149,92)-(149,108),0:FOR L=1 TO 66:FOR J=1 TO 5:NEXT J:PRESET (149,(114+L)):NEXT L:RETURN
12335 GOTO 12310
12340 '*
12350 GOSUB 154:LINE (167,93)-(167,108),2:FOR L=1 TO 66:FOR J=1 TO 5:NEXT J:PSET (167,(114+L)),3:NEXT L
12360 F$=INKEY$:IF F$<>"3" THEN 12360
12365 BEEP
12370 IF FX3=2 THEN PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
12380 FX3=FX3+1:GOSUB 166:IF RN<81 THEN FIRE=0:LINE (167,93)-(167,108),0:FOR L=1 TO 66:FOR J=1 TO 5:NEXT J:PRESET (167,(114+L)):NEXT L: RETURN
12385 GOTO 12360
12390 '*
12400 GOSUB 154:LINE (175,92)-(175,109),2:FOR L=1 TO 88:FOR J=1 TO 5:NEXT J:PSET (175,(110+L)),3:NEXT L
12410 F$=INKEY$:IF F$<>"4" THEN 12410
12415 BEEP
12420 IF FX4=2 THEN PRINT:PRINT " BAIL OUT !!!!":GOTO 31310
12430 FX4=FX4+1:GOSUB 166:IF RN<81 THEN FIRE=0:LINE (175,92)-(175,109),0:FOR L=1 TO 88:FOR J=1 TO 5:NEXT J:PRESET (175,(110+L)):NEXT L:RETURN
12435 GOTO 12410
13000 '*
13010 IF PLOTX=TX AND PLOTY=TY THEN LOCATE 2,1:PRINT "OVER TARGET      ":GOTO 13020
13015 FOR F=1 TO 3:PRESET (108+VX,52+VY):FOR T=1 TO 20:NEXT T:PSET (108+VX,52+VY):NEXT F:LOCATE 2,1:IF OVER=1 THEN PRINT "OVER WATER       " ELSE PRINT "OVER LAND        "
13020 IF B=1 THEN FUEL=FUEL+1.25:LB=0
13025 IF C(2)>0 AND ALT<>TA THEN GOSUB 180:FUEL=FUEL-RN
13030 IF B=0 THEN LB=.5
13040 FUEL=INT(FUEL-FX)
13050 ED=E(1)+E(2)+E(3)+E(4)+LB
13060 IF ED=1.5 THEN SL=1:FW(2)=1
13070 IF ED=2 THEN SL=1:FW(2)=2
13080 IF ED=2.5 THEN SL=2:FW(2)=3
13090 IF ED=3 THEN ALT=ALT-1250
13091 IF SL>0 THEN TA=-1
13092 IF ALT=TA AND SL<1.5 THEN FW(3)=-1
13093 IF AA=1 AND ALT>15000 THEN ALT=15000
13094 IF ALT<>TA THEN FW(3)=1
13100 IF ED>3 THEN ALT=0:LD=LD+10
13110 IF E(1)=1.5 THEN FUEL=FUEL-1.9
13120 IF E(2)=1.5 THEN FUEL=FUEL-1.9
13130 IF E(3)=1.5 THEN FUEL=FUEL-1.9
13140 IF E(4)=1.5 THEN FUEL=FUEL-1.9
13150 IF FUEL<1 THEN ALT=0
13152 IF ALT<1 THEN GOTO 31110
13160 FOR J=1 TO 4:IF E(J)>0 THEN 13190
13170 IF O(J)>0 THEN O(J)=O(J)+.25
13180 IF O(J)>10 THEN LOCATE 2,1:PRINT "ENG ";J;" OUT      ":E(J)=1:BEEP:FOR I=1 TO 2000:NEXT I
13190 NEXT J
13200 GOSUB 19000
13205 IF ALT<15000 THEN RETURN
13210 FB=ALT/5000
13220 GOSUB 170:IF B(1)=1 AND RN<FB THEN PRINT NB$;C6$:GP=GP-300:OT=OT+.2:G(1)=0
13230 GOSUB 170:IF B(2)=1 AND RN<FB THEN PRINT NC$;C6$:GP=GP-300:RX=RX+10:G(2)=0:G(3)=0
13240 GOSUB 170:IF B(3)=1 AND RN<FB THEN PRINT NA$;C6$:GP=GP-300:LD=LD+10:PP=1
13250 GOSUB 170:IF B(4)=1 AND RN<FB THEN PRINT NJ$;C6$:GP=GP-300:LD=LD+5
13260 GOSUB 170:IF B(5)=1 AND RN<FB THEN PRINT ND$;C6$:GP=GP-300:G(4)=0
13270 GOSUB 170:IF B(6)=1 AND RN<FB THEN PRINT NI$;C6$:GP=GP-300:RX=RX+5
13280 GOSUB 170:IF B(7)=1 AND RN<FB THEN PRINT NE$;C6$:GP=GP-300:G(7)=0
13290 GOSUB 170:IF B(8)=1 AND RN<FB THEN PRINT NF$;C6$:GP=GP-300:G(5)=0
13300 GOSUB 170:IF B(9)=1 AND RN<FB THEN PRINT NG$;C6$:GP=GP-300:G(6)=0
13310 GOSUB 170:IF B(10)=1 AND RN<FB THEN PRINT NH$;C6$:GP=GP-300:G(8)=0
13990 RETURN
14000 '*
14005 COLOR 0,CL:CALL ML1:CLS:PRINT " YOUR MISSION ALTITUDE IS ";MTA
14010 PRINT " FORWARD FIRE POWER       ";INT(((G(1)+GG+G(2)+G(3)+G(4)+G(7)+KA(1)+KA(2)+KA(3)+KA(4)+KA(6))/2)/.725);"%"
14020 PRINT " PORT FIRE POWER          ";INT(((G(4)+G(5)+G(7)+KA(4)+KA(7)+KA(6))/2)/.565);"%"
14030 PRINT " STARBORD FIRE POWER      ";INT(((G(4)+G(6)+G(7)+KA(4)+KA(8)+KA(6))/2)/.565);"%"
14040 PRINT " REAR FIRE POWER          ";INT(((G(4)+G(7)+G(8)+KA(4)+KA(6)+KA(9))/2)/.615);"%"
14060 BOEF=(OT*100)+(KA(1)/2): PRINT " BOMBING EFFICENCY        ";INT(BOEF/2);"%"
14070 LDG=LD*2.5 : PRINT " AIRCRAFT CONTROL RESPONSE ";INT((100)+((MISSION+KA(3))/4)-LDG):LOCATE 7,32:PRINT"%"
14080 IF RO=1 THEN PRINT " RADIO OUT"
14085 IF C(2)>1 AND ALT<>TA THEN PRINT " WE MAY BE LOST!"
14090 IF BBD=1 THEN PRINT " BOMB BAY DOORS WILL NOT OPEN"
14100 IF LRD=1 THEN PRINT " LIFE RAFT DESTROYED"
14110 IF E(1)=1 THEN PRINT " ENGINE #1 IS FEATHERED"
14120 IF E(2)=1 THEN PRINT " ENGINE #2 IS FEATHERED"
14130 IF E(3)=1 THEN PRINT " ENGINE #3 IS FEATHERED"
14140 IF E(4)=1 THEN PRINT " ENGINE #4 IS FEATHERED"
14150 IF E(1)=1.5 THEN PRINT " ENGINE #1 WINDMILLING"
14160 IF E(2)=1.5 THEN PRINT " ENGINE #2 WINDMILLING"
14170 IF E(3)=1.5 THEN PRINT " ENGINE #3 WINDMILLING"
14180 IF E(4)=1.5 THEN PRINT " ENGINE #4 WINDMILLING"
14190 IF O(1)>0 THEN PRINT " ENGINE #1 OIL LEAK"
14200 IF O(2)>0 THEN PRINT " ENGINE #2 OIL LEAK"
14210 IF O(3)>0 THEN PRINT " ENGINE #3 OIL LEAK"
14220 IF O(4)>0 THEN PRINT " ENGINE #4 OIL LEAK"
14230 IF FX>0 AND FX<4 THEN PRINT "MINOR FUEL LEAK"
14240 IF FX>3 THEN PRINT "LOOSING FUEL FAST"
14250 PRINT:PRINT "          HIT SPACE BAR TO RETURN"
14251 SP$=INKEY$:IF SP$=" "THEN CLS:COLOR 0,CL:CALL ML2:RETURN
14252 GOTO 14251
15000 '*
15010 IF E(1)>0 THEN LINE (138,75)-(144,75),3
15020 IF E(2)>0 THEN LINE (146,74)-(152,74),3
15030 IF E(3)>0 THEN LINE (164,74)-(170,74),3
15040 IF E(4)>0 THEN LINE (172,75)-(178,75),3
15050 RETURN
19000 '*
19001 IF PLOTX>17 OR PLOTY>10 THEN HP=HP+.25
19002 IF PLOTX>22 OR PLOTY>15 THEN HP=HP+.25
19003 IF W(1)>0 THEN RETURN
19004 IF W(2)>0 AND ALT=10000 THEN RETURN
19005 IF W(3)>0 AND ALT=15000 THEN RETURN
19006 IF W(4)>0 AND ALT=20000 THEN RETURN
19007 IF W(5)>0 AND ALT=25000 THEN RETURN
19008 IF W(6)>0 AND ALT=30000 THEN RETURN
19009 IF W(7)>0 AND ALT=35*1000 THEN RETURN
19010 IF PLOTX<29 AND PLOTY<4 THEN RETURN
19012 GOSUB 166:IF RN>26 THEN RETURN
19020 GOSUB 166:IF PLOTX<18 AND PLOTY<11 THEN RETURN
19030 IF PLOTX>26 OR PLOTY>19 THEN HP=HP+2:GOTO 19990
19035 IF PLOTX>22 OR PLOTY>15 THEN 19050
19040 IF RN<(65-MISSION) AND PLOTY<16 AND PLOTX<23 THEN RETURN
19050 IF RN<(55-MISSION) AND PLOTY>19 OR PLOTX>26 THEN RETURN
19070 LOCATE 2,1:PRINT "ESCORT ENGAGED   ":FOR H=1 TO 400:NEXT H:GOSUB 166:IF RN<(40+INT(MISSION/3))THEN LOCATE 2,1:PRINT "BANDITS DISPERSED":RETURN
19990 LOCATE 2,1:PRINT "                 ":CALL ML1:CLS
20000 '*
20010 PUT (119,75),B17A,XOR:PUT (162,75),B17B,XOR:PUT (155,70),B17C,PSET:PUT (143,108),B17D,XOR:GOSUB 15000
20015 IF SL>1 THEN 20040
20020 IF ALT=TA THEN PUT (5,150),B17,PSET:PUT (233,150),B17,PSET
20040 GOSUB 166:FW=INT(RN/33)+FW(2)+FW(1)+FW(3):IF FW<1 THEN FW=1
20042 FW=FW-1
20045 IF PLOTX>30 AND TX=38 AND TY=17 THEN FW=FW+1
20050 FOR W=0 TO FW:HP=HP+1:GOSUB 170:GOSUB 174:BANG=FXRN:BFLAG=0
20060 GOSUB 166:LOCATE 1,1
20062 IF RN<35 THEN LEVEL$="HIGH":LV=1
20064 IF RN>34 AND RN<67 THEN LEVEL$="LEVEL":LV=2
20066 IF RN>66 THEN LEVEL$="LOW":LV=3
20069 GOSUB 166:IF RN>40 AND RN<53 THEN VNH=50:VNV=82
20070 IF RN>52 AND RN<65 THEN VNH=249:VNV=82
20071 IF RN<13 THEN BOGY$=" 11 O'CLOCK ":VNH=75:VNV=5:VAV=1:VAH=1:VH=0:VV=1:GOTO 20100
20072 IF RN>12 AND RN<29 THEN BOGY$=" 12 O'CLOCK ":VNH=147:VNV=5:VAV=1:VAH=0:VH=1:VV=1:GOTO 20100
20074 IF RN>28 AND RN<41 THEN BOGY$=" 1 O`CLOCK ":VNH=214:VNV=5:VAV=1:VAH=-1:VH=0:VV=1:GOTO 20100
20076 IF RN>40 AND RN<45 THEN :PRINT"ME 109 @ 9 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=1:VH=1:VV=-1:GN=20:FOR T=1 TO 80:PUT(50+(VHP),82+(VVP)),ME109R,XOR:PUT(50+(VHP),82+(VVP)),ME109R,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25060:GOSUB 20:NEXT T:GOTO 24090
20078 IF RN>44 AND RN<49 THEN :PRINT"FW 190 @ 9 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=1:VH=1:VV=-1:GN=40:FOR T=1 TO 80:PUT(50+(VHP),82+(VVP)),FW190R,XOR:PUT(50+(VHP),82+(VVP)),FW190R,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25060:GOSUB 20:NEXT T:GOTO 24090
20080 IF RN>48 AND RN<53 THEN :PRINT"ME 110 @ 9 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=1:VH=1:VV=-1:GN=70:FOR T=1 TO 80:PUT(50+(VHP),82+(VVP)),ME110R,XOR:PUT(50+(VHP),82+(VVP)),ME110R,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25060:GOSUB 20:NEXT T:GOTO 24090
20082 IF RN>52 AND RN<57 THEN :PRINT"ME 109 @ 3 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=-1:VH=-1:VV=-1:GN=20:FOR T=1 TO 80:PUT(249+(VHP),82+(VVP)),ME109L,XOR:PUT(249+(VHP),82+(VVP)),ME109L,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25100:GOSUB 20:NEXT T:GOTO 24090
20084 IF RN>56 AND RN<61 THEN :PRINT"FW 190 @ 3 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=-1:VH=-1:VV=-1:GN=40:FOR T=1 TO 80:PUT(249+(VHP),82+(VVP)),FW190L,XOR:PUT(249+(VHP),82+(VVP)),FW190L,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25100:GOSUB 20:NEXT T:GOTO 24090
20086 IF RN>60 AND RN<65 THEN :PRINT"ME 110 @ 3 O'CLOCK ";LEVEL$;"    ":VAV=0:VAH=-1:VH=-1:VV=-1:GN=70:FOR T=1 TO 80:PUT(249+(VHP),82+(VVP)),ME110L,XOR:PUT(249+(VHP),82+(VVP)),ME110L,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25100:GOSUB 20:NEXT T:GOTO 24090
20088  IF RN>64 AND RN<77 THEN BOGY$="  7 O'CLOCK ":VNH=75:VNV=159:VAV=-1:VAH=1:VH=0:VV=-1:GOTO 20400
20090 IF RN>76 AND RN<89 THEN BOGY$="  6 O'CLOCK ":VNH=147:VNV=159:VAV=-1:VAH=0:VH=-1:VV=-1:GOTO 20400
20092 IF RN>88 THEN BOGY$=" 5 O`CLOCK ":VNH=214:VNV=159:VAV=-1:VAH=-1:VH=0:VV=-1:GOTO 20400
20100 GOSUB 166
20110 IF RN<33 THEN GN=20:PRINT "ME 109 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),ME109D,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),ME109D,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25010:GOSUB 20:NEXT T:GOTO 24090
20120 IF RN<67 AND RN>32 THEN GN=40:PRINT"FW 190 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),FW190D,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),FW190D,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25010:GOSUB 20:NEXT T:GOTO 24090
20130 IF RN>66 THEN GN=70:PRINT"ME 110 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),ME110D,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),ME110D,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25010:GOSUB 20:NEXT T:GOTO 24090
20400 GOSUB 166
20410 IF RN<33 THEN GN=20:PRINT "ME 109 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),ME109U,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),ME109U,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25135:GOSUB 20:NEXT T:GOTO 24090
20420 IF RN<67 AND RN>32 THEN GN=40:PRINT"FW 190 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),FW190U,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),FW190U,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25135:GOSUB 20:NEXT T:GOTO 24090
20430 IF RN>66 THEN GN=70:PRINT"ME 110 @ ";BOGY$;LEVEL$;"    ":FOR T=1 TO 90:PUT((VNH)+(VHP),(VNV)+(VVP)),ME110U,XOR:PUT((VNH)+(VHP),(VNV)+(VVP)),ME110U,XOR:VHP=VHP+VAH:VVP=VVP+VAV:GOSUB 25135:GOSUB 20:NEXT T:GOTO 24090
24090 VNH=0:VHP=0:VNV=0:VHP=0:VVP=0:VAH=0:VAV=0:NEXT W:LOCATE 1,1:PRINT"                                                                        "
24092 FW=0:FW(1)=0:FW(2)=0:FW(3)=0:GOTO 29910
25000 '*
25010 IF AMO(1)<1 THEN 25042
25015 LOCATE 1,30:PRINT "AMMO ";AMO(1)
25020 RTFIRE$=INKEY$:IF RTFIRE$=" " THEN KA=((G(1)+GG+G(2)+G(3)+G(4)+G(7)+KA(1)+KA(2)+KA(3)+KA(4)+KA(6))/2)+T:AMO(1)=AMO(1)- 1:LOCATE 1,30:PRINT "AMMO ";AMO(1);" ":IF AMO(1)<0 THEN LOCATE 1,30 : PRINT "AMMO OUT":KA=0:RETURN
25030 IF RTFIRE$=" " THEN GOSUB 170:GOSUB 14:IF FXRN<KA THEN 26000
25040 RETURN
25042 LOCATE 1,30:PRINT "AMMO OUT": RETURN
25050 '*
25060 IF AMO(2)<1 THEN 25042
25062 LOCATE 1,30:PRINT "AMMO ";AMO(2)
25065 RTFIRE$=INKEY$:IF RTFIRE$=" " THEN KA=((G(4)+G(5)+G(7)+KA(4)+KA(7)+KA(6))/2)+T:AMO(2)=AMO(2)-1:LOCATE 1,30:PRINT "AMMO ";AMO(2);" ":IF AMO(2)< 0 THEN LOCATE 1,30 : PRINT "AMMO OUT":KA=0:RETURN
25070 IF RTFIRE$=" " THEN GOSUB 170:GOSUB 14:IF FXRN<KA THEN 26000
25080 RETURN
25090 '*
25100 IF AMO(3)<1 THEN 25042
25102 LOCATE 1,30:PRINT "AMMO ";AMO(3)
25105 RTFIRE$=INKEY$:IF RTFIRE$=" " THEN KA=((G(4)+G(6)+G(7)+KA(4)+KA(8)+KA(6))/2)+T:AMO(3)=AMO(3)-1:LOCATE 1,30:PRINT "AMMO ";AMO(3);" ":IF AMO(3)<0 THEN LOCATE 1,30 : PRINT "AMMO OUT":KA=0:RETURN
25110 IF RTFIRE$=" " THEN GOSUB 170:GOSUB 14:IF FXRN<KA THEN 26000
25120 RETURN
25130 '*
25135 IF AMO(4)<1 THEN 25042
25137 LOCATE 1,30:PRINT "AMMO ";AMO(4)
25140 RTFIRE$=INKEY$:IF RTFIRE$=" " THEN KA=((G(4)+G(7)+G(8)+KA(4)+KA(6)+KA(9))/2)+T:AMO(4)=AMO(4)-1:LOCATE 1,30:PRINT "AMMO ";AMO(4);" ":IF AMO(4)<0 THEN LOCATE 1,30 : PRINT "AMMO OUT":KA=0:RETURN
25150 IF RTFIRE$=" " THEN GOSUB 170:GOSUB 14:IF FXRN<KA THEN 26000
25160 RETURN
26000 '*
26010 GOSUB 166:IF RN>83 THEN T=91:GOSUB 30:GP=GP+100:FKILL=FKILL+1:RETURN
26020 VAH=VH:VAV=VV:T=75:BFLAG=1:RETURN
29000 RETURN
29910  GET (119,75)-(154,93),B17A:GET (162,75)-(196,93),B17B:GET (155,70)-(161,107),B17C:GET (143,108)-(173,116),B17D
29912 CLS:COLOR 0,CL:CALL ML2:RETURN
30000 '*
30010 IF B>0 THEN RETURN
30020 FOR I=2000 TO 900 STEP-5:SOUND I,.5:NEXT I:FOR I=1 TO (BOMBS/10):PUT ((PLOTX*8)-8,(PLOTY*8)-8),FLA,XOR:GOSUB 12:FOR J=1 TO 200:NEXT J:PUT ((PLOTX*8)-8,(PLOTY*8)-8),FLA,XOR:NEXT I:B=1
30025 LD=LD-(INT(BMLD/10)):BMLD=0
30030 IF ACT$="a" OR ACT$="A"THEN:GP(1)=0:GOTO 30130
30040 IF PLOTX<>TX OR PLOTY<>TY THEN:GP(1)=-1000:GOTO 30130
30050 CC=0:IF ALT>=5000 THEN FOR X=1 TO ALT/5000:CC=CC+W(X):NEXT X:IF CC>0 THEN GP(1)=0:GOTO 30130
30100 IF OT<.1 THEN OT=.01
30110 GOSUB 166:GP(1)=INT(((OT*BOMBS*BOMBS*RN)/(ALT/100))/2):GP(1)=GP(1)+(KA(1)*4):IF GP(1)>1000 THEN GP(1)=1000
30112 IF ALT<>MTA THEN 30120
30114 IF ALT=25000 THEN HP=HP+1
30116 IF ALT=20000 THEN HP=HP+10
30118 IF ALT=15000 THEN HP=HP+20
30119 IF ALT=10000 THEN HP=HP+40
30120 IF GP(1)<1 THEN GP(1)=0
30130 BOMBS=GP(1):BL$="TARGET PTS ":LOCATE 23,21:PRINT BL$;BOMBS
30300 RETURN
31000 '*
31010 CLS:SCREEN 1,SS:LOCATE 1,1:FOR I=1 TO 24:PRINT "          |                 | ":NEXT I:L=0:OT=2:LD=LD+(INT(BMLD/10))
31015 FOR I=37 TO  53:SOUND I,5:NEXT I:SOUND 53,110
31020 X=0:FOR W=1 TO 35:PUT (119,(150-X)),B17,XOR:FOR I = 1 TO (200-L):NEXT I:L=L+10
31030 PUT (119,(150-X)),B17,XOR:X=X+4:NEXT W:X=0
31040 IF A$="Y" OR A$="y" THEN GOSUB 166:IF RN<11 THEN CLS:GOTO 31060
31050 GOTO 31090
31060 PUT (119,75),B17A,XOR:PUT (162,75),B17B,XOR:PUT (155,70),B17C,PSET:PUT (143,108),B17D,XOR:GOSUB 166:X=INT(RN/4)+1:IF X>4 THEN X=4
31062 E(X)=1:GOSUB 15000:GET (119,75)-(154,93),B17A:GET (162,75)-(196,93),B17B:GET (155,70)-(161,107),B17C:GET (143,108)-(173,116),B17D:FOR I=1 TO 1000:NEXT I:CALL ML2:ALT=0:RETURN
31090 ALT=5000:CALL ML2:RETURN
31100 '*
31105 IF B=0 THEN GP(1)=-1000
31110 IF W(1)>0 THEN LD=LD+10
31111 IF PLOTX=14 AND PLOTY=7 THEN OVER=0:GOTO 31114
31112 CLS:SCREEN 1,SS:IF OVER=0 THEN COLOR 2,15:LD=LD+5:L=0:LL=1:A=0:LOCATE 1,1:GOTO 31120
31113 IF OVER=1 THEN COLOR 1,15:LD=LD+10:L=0:LL=1:A=0:LOCATE 1,1:GOTO 31120
31114 CLS:LOCATE 1,1:FOR I=1 TO 24:PRINT "          |                 | " :NEXT I:L=0:LL=1:A=0:LOCATE 1,1:IF W(1)>0 THEN LD=LD+30
31115 FOR I=53 TO  37 STEP-1:SOUND I,5:NEXT I:SOUND 37,60
31120 FOR W=1 TO 25:PUT (119,(150-X+A)),B17,XOR:FOR E=1 TO L:NEXT E:L=L+10
31122 GOSUB 176:IF FHRN<INT((LD)-((MISSION+KA(3))/3)) THEN CRASH=4:W=22
31130 PUT (119,(150-X)),B17,XOR:X=X+4:NEXT W:IF CRASH=4 THEN PUT (113,(162-X)),B17A,XOR:PUT (167,(158-X)),B17B,XOR:PUT (155,(145-X)),B17C,XOR:PUT (146,(192-X)),B17D,XOR:GOTO 31150
31132 IF OVER=1 THEN:GOTO 31150
31134 IF A<1 AND PLOTX>20 OR PLOTY>9 THEN LOGO=LOGO+1
31140 IF A<1 THEN 31410
31150 FOR I=1 TO 9:IF C(I)>1 THEN C(I)=3:GP=GP-200:GOTO 31180
31160 GOSUB 166:FOR J=1 TO RN*10:NEXT J:GOSUB 166:IF RN>75 THEN C(I)=3:GP=GP-500:GOTO 31180
31170 PRINT "SURVIVOR EMERGES"
31180 NEXT I
31190 GOSUB 166:IF RN>85 THEN KI=1:GOTO 31220
31200 PRINT "YOU SURVIVE":FOR I=1 TO 1000:NEXT I:LOGO=LOGO +1:IF OVER=1 THEN LOGO=LOGO-1
31201 IF OVER =0 THEN 31410
31202 IF OVER=1 THEN:CLS:LOCATE 13,19:PRINT CHR$(8):LOCATE 1,1:PRINT " CREW WAITING FOR RESCUE":FOR I=1 TO 1000:NEXT I:GOSUB 166:IF RN+RX>80 THEN PRINT "CREW LOST AT SEA":FOR I=1 TO 1000:NEXT I:EG=1:GP=GP-4500:GOTO 31210
31206 LOGO=LOGO+1:GOTO 31500
31210 '*KIA*
31218 IF CPT=1 THEN PRINT RK$;" ";NA$;" HAS BEEN CAPTURED" :RK$=NA$:NA$="CAPTURED":EG=1:FOR I=1 TO 5000:NEXT I:GOTO 31230
31220 PRINT RK$;" ";NA$;" HAS BEEN KILLED IN ACTION" :RK$=NA$:NA$="DECEASED":EG=1:FOR I=1 TO 5000:NEXT I
31230 PP=3:GP=HP+GP(1)+GP:GOTO 31510
31300 '*BAIL OUT*
31310 BOT=10:BO$=INKEY$:SOUND 600,10:SOUND 32757,4:FOR I=1 TO 200:NEXT I:IF BO$=" " THEN 31312
31311 GOTO 31310
31312 CLS:PUT (119,75),B17A,XOR:PUT (162,75),B17B,XOR:PUT (155,70),B17C,PSET:PUT (143,108),B17D,XOR:GOSUB 15000
31314 FOR I=1 TO 9:IF C(I)>1 THEN C(I)=3:GP=GP-200:GOTO 31340
31320 GOSUB 171:FOR J=1 TO FXRN:NEXT J:GOSUB 166:IF RN>(90-BOT) THEN C(I)=3:GP=GP-500:GOTO 31340
31322 CHT=16:FOR M= 1 TO 8:LOCATE CHT,20:PRINT "!":FOR L =1 TO 20:NEXT L:LOCATE CHT,20:PRINT " ":CHT=CHT+1:NEXT M
31330 LOCATE 4,14:PRINT "PARACHUTE OPENS":FOR N= 1 TO 100:NEXT N:LOCATE 4,14:PRINT "                  "
31340 NEXT I
31350 GOSUB 166:IF RN >(98-BOT) THEN 31220
31355 CHT=16:FOR M= 1 TO 8:LOCATE CHT,20:PRINT "!":FOR L =1 TO 30:NEXT L:LOCATE CHT,20:PRINT " ":CHT=CHT+1:NEXT M
31360 LOCATE 4,10:PRINT "YOUR PARACHUTE OPENS":FOR I=1 TO 500:NEXT I:LOGO=LOGO+1
31370 IF OVER=1 THEN:CLS:LOCATE 1,1:PRINT " CREW WAITING FOR RESCUE":FOR I=1 TO 1000:NEXT I:GOSUB 166:IF RN+RX>70 THEN PRINT "CREW LOST AT SEA":FOR I=1 TO 1000:NEXT I:EG=1:GP=GP-4500:GOTO 31210
31400 '*
31410 IF PLOTX>20 OR PLOTY>9 THEN 31420
31415 GOTO 31510
31420 FOR I=1 TO 9:IF C(I)>1 THEN C(I)=3:GP=GP-200:GOTO 31450
31430 GOSUB 166:FOR J=1 TO RN*10:NEXT J:GOSUB 166:IF RN>75 THEN C(I)=3:GP=GP-500:GOTO 31450
31440 PRINT "CREW MEMBER GETS BACK TO ENGLAND"
31450 NEXT I
31460 GOSUB 166:IF RN>80 THEN PRINT "YOU ARE CAPTURED":CPT=1:EG=1:FOR I=1 TO 1000:NEXT I:GOTO 31220
31470 PRINT "YOU MAKE IT BACK":HP=HP+40:FOR I=1 TO 1000:NEXT I
31500 '*
31510 SCREEN 1:CLS:HP=HP*5:GX=6:IF MISSION>10 THEN GX=11
31520 IF MISSION=25 THEN GP=GP+2000:CLS:PRINT "  YOU HAVE BEEN AWARDED THE LEGION OF MERIT"
31530 IF GG>0 THEN 31550
31535 IF B=0 THEN GP(1)=-1000
31540 GOSUB 166:IF RN<GX THEN GG=20:PRINT "  YOUR 30 CAL. GUNS ARE NOW 50 CAL."
31550 GP=GP+GP(1)+HP:PRINT "  BOMB POINTS ";GP(1):PRINT "  MISSION EVALUATION ";HP:IF EG=1 THEN FOR X=1 TO 9:C(X)=3:NEXT X
31552 PRINT "  TOTAL NUMBER OF ENEMY KILLS ";FKILL
31555 PRINT "  TOTAL POINTS ";GP:IF EG=1 THEN 32010
31560 IF GP<0 THEN GP=0
31570 IF HP>700 AND HP<796 THEN H(2)=H(2)+1:GOSUB 31800
31580 IF HP>795 THEN H(3)=H(3)+1:GOSUB 31840
31590 IF GP>6999 AND GP<15000 AND H(1)=0 THEN RK$=R2$:H(1)=1:GOTO 31650
31610 IF GP>14999 AND GP<25000 AND H(1)=1 THEN RK$=R3$:H(1)=2:GOTO 31650
31620 IF GP>24999 AND GP<38*1000 AND H(1)=2 THEN RK$=R4$:H(1)=3:GOTO 31650
31630 IF GP>37*1000+999 AND GP<55*1000 AND H(1)=3 THEN RK$=R5$:H(1)=4:GOTO 31650
31640 IF GP>54999! AND H(1)=4 THEN RK$=R6$:H(1)=5:GOTO 31650
31642 IF MISSION=25 THEN 31650
31645 GOTO 31670
31650 PRINT "  CONGRATULATIONS ";RK$" ";NA$
31655 IF MISSION=25 THEN PRINT "  YOU ARE AWARDED THE LEGION OF MERIT"
31660 PRINT:PRINT "  TOTAL POINTS TO DATE ";GP
31670 IF PP=1 THEN GOSUB 166:IF RN >35 THEN PRINT "  RECOVERED AND RETURNED TO DUTY":PP=2
31680 IF PP=1 THEN PRINT "  YOU ARE AWARDED THE PURPLE HEART AND WILL BE SENT HOME ":EG=1:PP=3
31690 IF PP=2 THEN PRINT "  YOU ARE AWARDED THE PURPLE HEART"
31700 PRINT "  TOTAL MISSIONS TO DATE. ";MISSION
31710 IF MISSION=50 THEN FOR X=1 TO 9:C(X)=3:NEXT X:EG=1
31711 IF LOGO=10 THEN PRINT:PRINT:PRINT " YOU WERE SHOT BY A CREW MEMBER WHO CONFESSED THAT YOU WERE BETER OFF DEAD AFTER LOSING 10 GOOD AIRCRAFT AND SO MANY GOOD MEN.":FOR I=1 TO 6000:NEXT I:GOTO 31220
31730 GOTO 32010
31800 '*
31810 IF H(2)>0 OR H(3)>0 THEN PRINT "  YOU ARE AWARDED":PRINT
31820 IF H(2)=1 THEN PRINT "  THE ";R7$
31830 IF H(2)>1 THEN PRINT "  THE ";R7$;" WITH ";(H(2))-1;" OAKLEAF CLUSTER"
31831 RETURN
31840 IF H(2)>0 OR H(3)>0 THEN PRINT "  YOU ARE AWARDED":PRINT
31842 IF H(3)=1 THEN PRINT "  THE ";R8$
31850 IF H(3)>1 THEN PRINT "  THE ";R8$;" WITH ";(H(3))-1;" OAKLEAF CLUSTER"
31860 RETURN
32000 '*
32010 OPEN "O",#1,"VARIBLES"
32012 PRINT #1,C(1),C(2),C(3),C(4),C(5),C(6),C(7),C(8),C(9),KA(1),KA(2),KA(3),KA(4),KA(5),KA(6),KA(7),KA(8),KA(9),NX,H(3),GG,H(1),H(2),GP,LL,YES:PRINT #1,NA$:PRINT #1,RK$:PRINT #1,NB$:PRINT #1,NC$:PRINT #1,ND$:PRINT #1,NE$:PRINT #1,NF$
32014 PRINT #1,NG$:PRINT #1,NH$:PRINT #1,NI$:PRINT #1,NJ$:PRINT #1,MISSION:PRINT #1,LOGO:PRINT #1,SS:PRINT #1,CL:PRINT #1,FKILL:CLOSE 1
32015 IF EG=1 THEN 32100
32016 IF MISSION=50 THEN 32100
32017 CZ=1:OPEN "O",#2,"CHECK":PRINT #2,CZ:CLOSE 2
32018 PRINT:PRINT "          SAVE GAME FOR LATER ";:INPUT G$:IF G$="Y" OR  G$="y" THEN EM=1
32019 IF G$="Y" OR G$="y" THEN PRINT "           CONTINUE Y/N";:INPUT C$:IF C$="Y" OR C$="y" THEN CLEAR:CG=1:GOTO 8
32020 IF EM=1 THEN END
32021 SHAPE=0:B=0:FOR X=1 TO 4:O(X)=0:E(X)=0:NEXT X:LD=0:BOEF=0:OT=0:LDG=0:RO=0:LRD=0:FX=0:SL=0:LB=0:ED=0:FX1=0:FX2=0:FX3=0:FX4=0:FX5=0
32022 HP=0:GP(1)=0:GP=0:CRASH=0:PLOTX=14:PLOTY=7:BBD=0:FOR X=1 TO 10:B(X)=0:NEXT X:VY=0:VX=0:RR=0:LR=0:RX=0:SR=0:B=0:AA=0
32030 OPEN "I",#1,"VARIBLES"
32040 INPUT #1,C(1),C(2),C(3),C(4),C(5),C(6),C(7),C(8),C(9),KA(1),KA(2),KA(3),KA(4),KA(5),KA(6),KA(7),KA(8),KA(9),NX,H(3),GG,H(1),H(2),GP,LL,YES:INPUT #1,NA$:INPUT #1,RK$:INPUT #1,NB$:INPUT #1,NC$:INPUT #1,ND$:INPUT #1,NE$:INPUT #1,NF$
32042 INPUT #1,NG$:INPUT #1,NH$:INPUT #1,NI$:INPUT #1,NJ$:INPUT #1,MISSION:INPUT #1,LOGO:INPUT #1,SS:INPUT #1,CL:INPUT #1,FKILL:CLOSE 1
32044 OPEN "I",#2,"CHECK":INPUT #2,CZ:CLOSE 2
32046 IF MISSION=50 THEN 32100
32048 IF LX=1 THEN LX=0:GOTO 8
32050 GOTO 8
32100 '*
32110 PRINT:PRINT:PRINT RK$;" ";NA$:PRINT:PRINT "YOUR FINAL SCORE IS ";GP
32120 IF EG=1 AND MISSION<50 THEN 32140
32130 PRINT:PRINT "YOU HAVE COMPLEETED THE TOUR OF DUTY":PRINT:PRINT "YOU ARE AWARDED THE DISTINGUISHED SERVICE MEDAL"
32140 PRINT:PRINT "ACCUMULATED DECORATIONS"
32150 IF PP>0 THEN PRINT:PRINT "THE PURPLE HEART"
32160 IF MISSION>24 THEN PRINT:PRINT "THE LEGION OF MERIT"
32170 IF H(2)=1 THEN PRINT:PRINT "THE ";R7$
32180 IF H(2)>1 THEN PRINT:PRINT "THE ";R7$;" WITH ";H(2);" OAKLEAF CLUSTER"
32190 IF H(3)=1 THEN PRINT:PRINT "THE ";R8$
32200 IF H(3)>1 THEN PRINT:PRINT "THE ";R8$;" WITH ";H(3);" OAKLEAF CLUSTER"
32210 END
40000 '*
40002 SCREEN 1:IF YES=1 THEN 40040
40003 IF CG=1 THEN 40012
40004 LOCATE 12,8:PRINT "DO YOU HAVE A RGB MONITOR";:INPUT S$:IF S$="Y" OR S$="y" THEN SS=1:CL=0:GOTO 40012
40006 SS=0:CL=1
40012 CLS:LOCATE 14,5:PRINT "IS THIS YOUR FIRST MISSION? Y/N";:INPUT Y$:IF Y$="Y" OR Y$="y" THEN FOR X=1 TO 9:YES=1:RK$=R1$:C(X)=3:NEXT X:CZ=1:CLS
40013 IF YES=0 THEN 32030
40014 LOCATE 12,6:PRINT "WHAT IS YOUR NAME";:INPUT NA$
40020 CLS:PRINT RK$;" ";NA$
40030 PRINT:PRINT "WELCOME TO THE 8TH AIR FORCE 306TH BOMB GROUP.":FOR I=1 TO 500:NEXT I
40040 IF CZ=0 THEN GP=0:GOTO 31220
40042 PRINT:PRINT "HAVE A GOOD NIGHT'S SLEEP AND REPORT TO THE BRIEFING AT 0400":FOR I=1 TO 500:NEXT I:CZ=0:OPEN "O",#2,"CHECK":PRINT #2,CZ:CLOSE 2
40050 IF MISSION>5 THEN GOSUB 198:GOSUB 55010
40055 IF MISSION<6 THEN GOSUB 160:GOSUB 55010
40060 SCREEN 1:CLS:PRINT "GOOD MORNING ";RK$;" ";NA$:PRINT
40062 PRINT "YOUR TOTAL MISSION POINTS ";GP:PRINT
40064 PRINT "THE TARGET TO-DAY IS ";TARGET$:PRINT
40066 GOSUB 166:IF RN<16 THEN LET TA=30000
40068 IF RN>15 AND RN<36 THEN TA=25000
40070 IF RN>35 AND RN<66 THEN TA=20000
40072 IF RN>65 AND RN<86 THEN TA=15000
40074 IF RN>85 THEN TA=10000
40076 PRINT "YOUR ASSEMBLY ALTITUDE IS ";TA:PRINT:MTA=TA
40078 PRINT"YOUR AIRCRAFT IS ";SN$(LOGO):PRINT
40080 PRINT "HOW MUCH FUEL DO YOU WANT (1-100%)";:INPUT FU:PRINT:IF FU>100 THEN FU=100
40082 BOMBS=120-FU:IF BOMBS>100 THEN BOMBS=100
40084 FUEL=INT(FU*25.2):PRINT"WILL YOU RISK AN OVER LOAD (Y-N) ";:INPUT A$:IF A$="Y" OR A$="y" THEN BOMBS=BOMBS+20:BL(1)=1:FOR I=1 TO 1500:NEXT I
40086 G(1)=20:G(2)=20:G(3)=20:G(4)=40:G(5)=30:G(6)=30:G(7)=40:G(8)=40:FOR X=1 TO 4:AMO(X)=30:NEXT X:BMLD=BOMBS
40100 CLS:RETURN
44060 IF RN<31 AND RN>15 THEN PRINT CB$;C2$:B(1)=1:FXRN=150:FYRN=64:PRESET (157,72):RETURN
44460 IF RN<31 AND RN>15 THEN PRINT CB$;C2$:B(1)=1:FXRN=150:FYRN=64:PRESET (157,72):RETURN
50000 '*
50010 SN$(0)="IMPATIENT VIRGIN":SN$(1)="BANSHEE":SN$(2)="JOAN OF ARC":SN$(3)="SWEET PEA":SN$(4)="SUN OF FURY":SN$(5)="LITTLE AUDREY"
50020 SN$(6)="ROSE OF YORK":SN$(7)="GEEZIL II":SN$(8)="WAHOO":SN$(9)="WAHOO II"
50030 CA$="PILOT":CC$="COPILOT":CB$="BOMBARDIER":CN$="NAVIGATOR":CE$="ENGINEER":CR$="RADIOMAN":CG$="BALL GUNNER"
50040 CS$="STBD. GUNNER":CP$="PORT GUNNER":CT$="TAIL GUNNER":C1$=" OXYGEN OUT":C2$=" HEATER OUT":C3$=" IS HURT":C4$=" IS BADLY HURT":C5$=" IS DEAD":C6$=" HAS FROSTBITE"
50050 R1$="LIEUTENANT":R2$="CAPTAIN":R3$="MAJOR":R4$="LT.COLONEL
50060 R5$="COLONEL":R6$="BRIGADIER GEN.":R7$="AIR MEDAL":R8$="DISTINGUISHED FLYING CROSS":BL$="BOMB LOAD":RETURN
50100 '*
50102 SCREEN 1
50110 IF YES=1 THEN CLS:GOTO 50120
50120 PRINT "       NEW CREW MEMBER NAME ?"
50130 PRINT"      LIMIT NAME TO 13 LETTERS":PRINT
50140 IF C(1)>2 THEN C(1)=1:PRINT CB$;:INPUT NB$:KA(1)=0
50150 IF C(2)>2 THEN C(2)=1:PRINT CN$;:INPUT NC$:KA(2)=0
50160 IF C(3)>2 THEN C(3)=1:PRINT CC$;:INPUT NJ$:KA(3)=0
50170 IF C(4)>2 THEN C(4)=1:PRINT CE$;:INPUT ND$:KA(4)=0
50180 IF C(5)>2 THEN C(5)=1:PRINT CR$;:INPUT NI$:KA(5)=0
50190 IF C(6)>2 THEN C(6)=1:PRINT CG$;:INPUT NE$:KA(6)=0
50200 IF C(7)>2 THEN C(7)=1:PRINT CP$;:INPUT NF$:KA(7)=0
50210 IF C(8)>2 THEN C(8)=1:PRINT CS$;:INPUT NG$:KA(8)=0
50220 IF C(9)>2 THEN C(9)=1:PRINT CT$;:INPUT NH$:KA(9)=0
50222 FOR I=1 TO 500:NEXT I:HFLACK=0
50224 FOR X =1 TO 9:C(X)=1: NEXT X
50230 CLS:PRINT "     CREW                       MISSION":PRINT:PRINT CB$,NB$:PRINT CN$,NC$:PRINT CC$,NJ$:PRINT CE$,ND$:PRINT CR$,NI$:PRINT CG$,NE$:PRINT CP$,NF$:PRINT CS$,NG$:PRINT CT$,NH$
50235 FOR BERT = 3 TO 11:LOCATE BERT,35:PRINT KA(BERT-2):NEXT BERT
50240 PRINT:PRINT:PRINT"      HIT SPACE TO CONTINUE"
50250 CONTI$=INKEY$:GOSUB 166:IF CONTI$<>" "THEN 50250
50260 FOR X=1 TO 9:KA(X)=KA(X)+1:NEXT X
55000 RETURN
55010 '*
55020 OT=1:IF RN>0 AND RN<5 THEN TX=19:TY=12:TARGET$="ST.OMER"
55030 IF RN>4 AND RN<9 THEN TX=7:TY=13:TARGET$="CHERBOURG"
55040 IF RN>8 AND RN <12 THEN TX=18:TY=17:TARGET$="AMIENS"
55050 IF RN>11 AND RN<15 THEN TX=20:TY=16:TARGET$="MEAULTE"
55060 IF RN>14 AND RN<18 THEN TX=17:TY=14:TARGET$="ABBEVILLE
55070 IF RN>17 AND RN<20 THEN TX=38:TY=17:TARGET$="SCHWEINFURT"
55080 IF RN>19 AND RN<23 THEN TX=22:TY=14:TARGET$="LILLE"
55090 IF RN>22 AND RN<26 THEN TX=26:TY=10:TARGET$="ROTTERDAM"
55100 IF RN>25 AND RN<29 THEN TX=26:TY=13:TARGET$="ANTWERP"
55110 IF RN>28 AND RN<32 THEN TX=6:TY=17:TARGET$="ROUEN"
55120 IF RN>31 AND RN<35 THEN TX=17:TY=20:TARGET$="PARIS"
55130 IF RN>34 AND RN<38 THEN TX=18:TY=22:TARGET$="ROMILLY SUR SEINE"
55140 IF RN>37 AND RN<41 THEN TX=6:TY=19:TARGET$="RENNES"
55150 IF RN>40 AND RN<44 THEN TX=1:TY=16:TARGET$="BREST"
55160 IF RN>43 AND RN<47 THEN TX=3:TY=20:TARGET$="LORIENT"
55170 IF RN>46 AND RN<50 THEN TX=4:TY=22:TARGET$="ST.NAZAIRE"
55180 IF RN>49 AND RN<53 THEN TX=35:TY=5:TARGET$="WILHEIMSHAVEN"
55190 IF RN>52 AND RN<56 THEN TX=34:TY=6:TARGET$="EMDEN"
55200 IF RN>55 AND RN<59 THEN TX=36:TY=7:TARGET$="VEGESACK"
55210 IF RN>58 AND RN<62 THEN TX=37:TY=8:TARGET$="BREMEN"
55220 IF RN>61 AND RN<65 THEN TX=35:TY=11:TARGET$="HAMM"
55230 IF RN>64 AND RN<68 THEN TX=4:TY=25:TARGET$="LA ROCHELLE"
55240 IF RN>67 AND RN<71 THEN TX=40:TY=2:TARGET$="KIEL"
55300 RETURN
58000 '*
58001 RESTORE 58005:ML$=SPACE$(76):ML1=VARPTR(ML$)
58002 ML1=PEEK(ML1+1)+PEEK(ML1+2)*256
58003 FOR ML3=0 TO 67:READ ML4:POKE ML1+ML3,ML4:NEXT
58004 ML2=ML1+34:RETURN
58005 DATA &H55,&H1E,&H06,&H8C,&HDB,&H81,&HC3,&H00,&H10,&H8E,&HC3,&HBB,&H00
58006 DATA &HB8,&H8E,&HDB,&HB9,&H00,&H20,&HFC,&HBE,&H00,&H00,&HBF,&H00,&H00
58007 DATA &HF3,&HA5,&H07,&H1F,&H5D,&HCA,&H00,&H00
58008 DATA &H55,&H1E,&H06,&H8C,&HDB,&H81,&HC3,&H00,&H10,&H8E,&HDB,&HBB,&H00
58009 DATA &HB8,&H8E,&HC3,&HB9,&H00,&H20,&HFC,&HBE,&H00,&H00,&HBF,&H00,&H00
58010 DATA &HF3,&HA5,&H07,&H1F,&H5D,&HCA,&H00,&H00
